Không thể tính toán sự khác biệt giữa maxBound và minBound của một kiểu Enum?

Question

Tôi có quyền kết luận rằng không có cách nào để tính maxBound - minBound trong Haskell cho một loại tùy ý Enum và Bounded? Hoặc tôi thiếu một số thủ thuật/hack? Đây là những gì tôi có, mà rõ ràng là không thể làm việc:

difference :: (Enum a, Bounded a) => Int 
difference = fromEnum maxBound - fromEnum minBound 

Lỗi:

Foo.hs:37:1: 
    Ambiguous constraint `Enum a' 
     At least one of the forall'd type variables mentioned by the constraint 
     must be reachable from the type after the '=>' 
    In the type signature for `difference': difference :: (Enum a, Bounded a) => Int 

Foo.hs:37:1: 
    Ambiguous constraint `Bounded a' 
     At least one of the forall'd type variables mentioned by the constraint 
     must be reachable from the type after the '=>' 
    In the type signature for `difference': difference :: (Enum a, Bounded a) => Int 

Tôi hiểu tại sao tôi nhận được rằng lỗi không có hạn thực tế trong đó có loại a, vì vậy nó không thể tìm ra những gì a là. Câu hỏi đặt ra là liệu có cách nào để giải quyết vấn đề này không.

Answer 1

Sử dụng Proxy để chỉ định loại bạn muốn và sử dụng ScopedTypeVariables để đưa loại đó vào phạm vi trong định nghĩa chức năng của bạn.

{-# LANGUAGE ScopedTypeVariables #-} 

data Proxy a = Proxy 

difference :: forall a . (Enum a, Bounded a) => Proxy a -> Int 
difference Proxy = fromEnum (maxBound :: a) - fromEnum (minBound :: a) 

>>> difference (Proxy :: Proxy Bool) 
1 

Edit: Sử dụng gợi ý của Daniel:

data Proxy a = Proxy 

difference :: (Enum a, Bounded a) => Proxy a -> Int 
difference p = fromEnum (max' p) - fromEnum (min' p) where 
    max' :: (Bounded a) => Proxy a -> a 
    max' Proxy = maxBound 
    min' :: (Bounded a) => Proxy a -> a 
    min' Proxy = minBound 

Answer 2

difference :: (Enum a, Bounded a) => a -> Int 
difference x = fromEnum (maxBound `asTypeOf` x) 
      - fromEnum (minBound `asTypeOf` x) 

Gọi nó như ví dụ difference (undefined :: Char).

Nhưng lưu ý rằng điều này sẽ tràn cho một số loại (đáng chú ý nhất Int), do đó thay vì sử dụng một Integer kết quả:

difference :: (Enum a, Bounded a) => a -> Integer 
difference x = toEnum (fromEnum (maxBound `asTypeOf` x)) 
      - toEnum (fromEnum (minBound `asTypeOf` x))