Opacity điều khiển cho bao phủ lô

Question

Cho hai lô vector và một âm mưu đường viền như sau

as = VectorPlot[{Cos[y], Sin[x] }, {x, -3, 3}, {y, -3, 3}, 
       VectorScale -> Automatic, VectorColorFunction -> "Rainbow" 
    ]; 
bs = StreamPlot[{Cos[y], Sin[x] }, {x, -3, 3}, {y, -3, 3}, 
       VectorScale -> Automatic, StreamColorFunction -> "Rainbow" 
    ]; 
cs = ContourPlot[Cos[x] + Sin[y], {x, -3, 3}, {y, -3, 3}, 
       ColorFunction -> "BlueGreenYellow" 
    ]; 
Show[cs, bs, as] 

chúng ta có thể thấy việc chồng cơ bản cũng được thực hiện bằng diễn ảnh []. Nhưng câu hỏi của tôi là làm cách nào tôi có thể kiểm soát độ mờ của đường viền nền cs? Ngoài ra, làm cách nào tôi có thể chèn các lược đồ kiểu màu "BlueGreenYellow" vào một chức năng màu như sau?

ContourPlot[Cos[x] + Sin[y], {x, -3, 3}, {y, -3, 3}, 
      ColorFunction -> (Directive[Opacity[#],Blue] &) 
]; 

Answer 1

Bạn có thể thử sử dụng BaseStyle như sau:

cs = ContourPlot[Cos[x] + Sin[y], {x, -3, 3}, {y, -3, 3}, 
       ColorFunction -> "BlueGreenYellow", 
       BaseStyle -> Directive[Opacity[0.5]] 
    ]; 

Answer 2

Tôi không tin rằng jmlopez' giải pháp là đúng, bởi vì các vectơ và khung cũng là một phần trong suốt. Tôi tin rằng nó là tốt hơn để chèn một lệnh Opacity vào đối tượng Graphics, mà sẽ giữ gìn vectơ đục:

as = VectorPlot[{Cos[y], Sin[x]}, {x, -3, 3}, {y, -3, 3}, 
     VectorScale -> Automatic, VectorColorFunction -> "Rainbow"]; 
bs = StreamPlot[{Cos[y], Sin[x]}, {x, -3, 3}, {y, -3, 3}, 
     VectorScale -> Automatic, StreamColorFunction -> "Rainbow"]; 
cs = ContourPlot[Cos[x] + Sin[y], {x, -3, 3}, {y, -3, 3}, 
     ColorFunction -> "BlueGreenYellow"]; 

cs2 = MapAt[{Opacity[0.5], #} &, cs, 1]; 

Show[cs2, bs, as] 

---

Câu hỏi thứ hai không bao giờ được giải quyết. Bạn có thể kết hợp độ mờ đục và một gradient màu như thế này:

ContourPlot[Cos[x] + Sin[y], {x, -3, 3}, {y, -3, 3}, 
    ColorFunction -> ({Opacity[#], ColorData["BlueGreenYellow"][#]} &) 
]