Làm cách nào để tìm các thành phần nằm trong một mảng nhưng không tìm thấy phần tử khác trong Perl?

Question

Tôi có hai mảng và tôi muốn tìm các yếu tố có trong một mảng nhưng không khác:

ví dụ:

@array1 = ("abc", "cde", "fgh", "ijk", "lmn") 
@array2 = ("abc", "fgh", "lmn") 

tôi cần phải kết thúc với:

@array3 = ("cde", "ijk") 

Answer 1

my @array3; 
foreach my $elem (@array1) 
{ 
    if(!grep($elem eq $_, @array2)) 
    { 
     push(@array3, $elem); 
    } 
} 

Answer 2

Xem How do I compute the difference of two arrays? How do I compute the intersection of two arrays? trong perlfaq4.

Answer 3

Đặt các phần tử của mảng thứ hai vào một băm, để kiểm tra hiệu quả để xem có hay không một yếu tố đặc biệt được trong nó, sau đó lọc mảng đầu tiên cho chỉ những yếu tố mà không được trong mảng thứ hai:

my %array2_elements; 
@array2_elements{ @array2 } =(); 
my @array3 = grep ! exists $array2_elements{$_}, @array1; 

Answer 4

my %total; 
$total{$_} = 1 for @array1; 
delete $total{$_} for @array2; 
my @diff = keys %total; 

Answer 5

Bạn có thể sử dụng mô-đun cpan được gọi là List::Compare.

use List::Compare; 
    my $lc = List::Compare->new(\@array1,\@array2); 
    my @newarray = $lc->get_symdiff; 

Answer 6

Sử dụng hàm băm làm bảng tra cứu. Khóa của nó là các phần tử của mảng thứ hai, các giá trị không quan trọng:

#!/usr/bin/env perl 
use strict; 
use warnings; 

my @array1 = ("abc", "cde", "fgh", "ijk", "lmn"); 
my @array2 = ("abc", "fgh", "lmn"); 

my @array1only; 

# build lookup table 
my %seen; 
foreach my $elem (@array2) { 
    $seen{$elem} = 1; 
} 

# find elements present only in @array1 
foreach my $elem (@array1) { 
    push @array1only, $elem unless $seen{$elem}; 
} 

print "Elements present only in \@array1: ", join(", ", @array1only), "\n"; 

Để biết thêm công thức 4.8 trong Perl Cookbook.