Làm cách nào để bắt ngoại lệ trong sự kiện TDataModule.OnCreate?

Question

Tôi vui lòng yêu cầu bạn tư vấn về vấn đề sau tôi gặp phải ở Delphi với khối try/except.

Tôi có một ứng dụng đơn giản - một trong những MainForm có tên fr_MAIN và một TDataModule có tên DM. DM không phải là tính năng tự động tạo ra, nhưng nó được tạo ra tại thời gian chạy trong fr_MAIN 's Button2.OnClick sự kiện:

procedure Tfr_MAIN.Button2Click(Sender: TObject); 
begin 
    try 
    DM := TDM.Create(nil); 
    Showmessage('DM started!'); 
    except 
    on E:Exception do 
    begin 
     Showmessage('DM not started!'); 
    end; 
    end; 

DM có một số mã trong sự kiện OnCreate của nó:

procedure TDM.DataModuleCreate(Sender: TObject); 
begin 
    raise Exception.Create('this is error!'); 
    // DM code here ... 
end; 

Vấn đề là khi Tôi nhấp vào Button2, tôi nhận được thông báo ngoại lệ 'this is error!', phần còn lại của DM code here không chạy - điều đó là chính xác! Nhưng sau đó tôi cũng nhận được thông báo 'DM started!' thay vì thông báo 'DM not started!'.

Ngoại lệ được tăng lên bởi DM ngắt hành động nhưng không bị bắt trong khối except của biểu mẫu!

Tại sao điều này?

Answer 1

TDataModule có xử lý đặc biệt các ngoại lệ được nêu trong sự kiện OnCreate của nó.

Trường hợp ngoại lệ được xử lý ở đây:

procedure TDataModule.DoCreate; 
begin 
    if Assigned(FOnCreate) then 
    try 
    FOnCreate(Self); 
    except 
    if not HandleCreateException then // <-- here 
     raise; 
    end; 
end; 

function TDataModule.HandleCreateException: Boolean; 
begin 
    if Assigned(ApplicationHandleException) then 
    begin 
    ApplicationHandleException(Self); // <-- here 
    Result := True; 
    end 
    else 
    Result := False; 
end; 

Theo mặc định, TApplication gán TApplication.HandleException()-ApplicationHandleException:

constructor TApplication.Create(AOwner: TComponent); 
var 
    ... 
begin 
    inherited Create(AOwner); 
    ... 
    if not Assigned(System.Classes.ApplicationHandleException) then 
    System.Classes.ApplicationHandleException := HandleException; // <-- here 
    if not Assigned(System.Classes.ApplicationShowException) then 
    System.Classes.ApplicationShowException := ShowException; 
    ... 
end; 

Vì vậy, TDataModule.DoCreate() đang thu hút sự ngoại lệ và đi qua nó để TApplication.HandleException(), mà sau đó sẽ hiển thị một hộp thoại bật lên theo mặc định. Và kể từ TDataModule.HandleCreateException() sau đó trả về True, ngoại lệ bị bắt không được nâng lên. Ngoại lệ hiện được xem là đã xử lý, cho phép chương trình tiếp tục bình thường với cuộc gọi Showmessage('DM started!'); của nó.

Để tránh hộp thoại bật lên khi ngoại lệ xảy ra, bạn có thể gán một handler TApplication.OnException sự kiện:

Vcl.Forms.TApplication.OnException

Sử dụng OnException để thay đổi hành vi mặc định xảy ra khi một ngoại lệ không được xử lý bởi mã ứng dụng. Sự kiện OnException xử lý được gọi tự động trong phương thức HandleException.

Nhưng ngoại lệ vẫn sẽ bị bắt và loại bỏ bởi TDataModule.DoCreate(). Nếu bạn muốn tránh điều đó, do đó, ngoại lệ lan truyền lên ngăn xếp cuộc gọi, không nêu ngoại lệ từ sự kiện TDataModule.OnCreate. Ghi đè lên hàm tạo ảo TDataModule.Create() và tăng ngoại lệ từ đó lên thay thế.

: Điều tương tự cũng xảy ra trong TCustomForm.