Ví dụ Functor cho GADT có ràng buộc kiểu

Question

Hôm nay tôi muốn điều tra nếu có thể xây dựng kiểu dữ liệu theo cách sao cho nó không lưu trữ dữ liệu kiểu chữ ký của nó, nhưng đại diện khác của nó . Vì vậy, đây là nỗ lực của tôi về một GADT trong đó có một nhà xây dựng kiểu của loại a, nhưng một nhà xây dựng dữ liệu của loại ByteString.

{-# LANGUAGE GADTs #-} 
import Data.ByteString.Char8 
import Data.Serialize 

data Serialized a where 
    MkSerialized :: (Serialize a) => ByteString -> Serialized a 

Bây giờ tôi có thể định nghĩa một hàm decode' theo cách sau:

decode' :: (Serialize a) => Serialized a -> a 
decode' (MkSerialized bs) = let Right r = (decode bs) in r 

Và nó hoạt động:

let s = MkSerialized (encode "test") :: Serialized String 
print $ decode' s  -- prints "test" 

Vấn đề của tôi bây giờ là tôi muốn trở thành một Serialized ví dụ của Functor.

instance Functor Serialized where 
    fmap f (MkSerialized bs) = MkSerialized (encode (f (right (decode bs)))) 
           where right (Right r) = r 

Nhưng tôi gặp lỗi (Serialize b) không thể suy luận được. Làm thế nào tôi có thể hạn chế cá thể Functor để Serialize được thực thi trong fmap?

Answer 1

Bạn có thể thực hiện việc này bằng cách sử dụng CoYoneda functor.

Ý tưởng rất đơn giản: có trường chức năng bổ sung nơi bạn tích lũy các hàm ing fmap. Khi bạn giải mã giá trị của mình, hãy áp dụng hàm đó.

Dưới đây là các mã:

{-# LANGUAGE GADTs #-} 
import Data.ByteString.Char8 
import Data.Serialize 

data Serialized a where 
    MkSerialized 
     :: (Serialize a) 
     => ByteString -> (a -> b) -> Serialized b 

decode' :: Serialized a -> a 
decode' (MkSerialized bs f) = let Right r = decode bs in f r 

instance Functor Serialized where 
    fmap f (MkSerialized bs g) = MkSerialized bs (f . g) 

này cũng có lợi ích của tự động pha trộn nhiều fmap s thay vì decodings lặp đi lặp lại và mã hóa, như sẽ là trong trường hợp của bạn.