Làm cách nào để kiểm tra phần mở rộng của một tệp bằng Perl?

Question

Để tập lệnh perl của tôi, một tệp được chuyển thành một cuộc tranh luận. Tệp có thể là tệp .txt hoặc tệp .zip chứa tệp .txt.

Tôi muốn viết mã mà trông giống như sau

if ($file is a zip) { 

    unzip $file 
    $file =~ s/zip$/txt/; 
} 

Một cách để kiểm tra phần mở rộng là để làm một sự chia rẽ trên . và sau đó kết hợp các kết quả cuối cùng trong mảng (được trả về bởi split).

Có cách nào tốt hơn không?

Answer 1

Bạn có thể sử dụng Tệp :: Tên cơ sở cho việc này.

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 

use File::Basename; 

my @exts = qw(.txt .zip); 

while (my $file = <DATA>) { 
    chomp $file; 
    my ($name, $dir, $ext) = fileparse($file, @exts); 

    given ($ext) { 
    when ('.txt') { 
     say "$file is a text file"; 
    } 
    when ('.zip') { 
     say "$file is a zip file"; 
    } 
    default { 
     say "$file is an unknown file type"; 
    } 
    } 
} 

__DATA__ 
file.txt 
file.zip 
file.pl 

Chạy điều này mang lại:

$ ./files 
file.txt is a text file 
file.zip is a zip file 
file.pl is an unknown file type 

Answer 2

Làm cách nào để kiểm tra phần cuối của tên tệp?

if ($file =~ /\.zip$/i) { 

và sau đó:

use strict; 
use Archive::Extract; 

if ($file =~ /\.zip$/i) { 
    my $ae = Archive::Extract->new(archive => $file); 
    my $ok = $ae->extract(); 
    my $files = $ae->files(); 
} 

biết thêm thông tin here.

Answer 3

Bạn có thể kiểm tra phần mở rộng tập tin bằng một trận đấu regex như:

if($file =~ /\.zip$/i) { 
     # $file is a zip file 
} 

Answer 4

Tại sao dựa vào phần mở rộng tập tin? Chỉ cần cố giải nén và sử dụng xử lý ngoại lệ thích hợp:

eval { 
    # try to unzip the file 
}; 

if ($@) { 
    # not a zip file 
} 

Answer 5

Một giải pháp khác là sử dụng loại tệp nhị phân.

use strict; 
use warnings; 

use File::Type; 

my $file  = '/path/to/file.ext'; 
my $ft  = File::Type->new(); 
my $file_type = $ft->mime_type($file); 

if ($file_type eq 'application/octet-stream') { 
    # possibly a text file 
} 
elsif ($file_type eq 'application/zip') { 
    # file is a zip archive 
} 

Bằng cách này, bạn không phải xử lý các tiện ích bị thiếu/sai.

Answer 6

Tôi biết câu hỏi này là một vài tuổi, nhưng đối với bất cứ ai mà đến đây trong tương lai, một cách dễ dàng để phá vỡ một đường dẫn tập tin vào con đường cấu thành của nó , tên tệp, tên cơ sở và đuôi mở rộng như sau.

use File::Basename; 

my $filepath = '/foo/bar.txt'; 

my ($basename, $parentdir, $extension) = fileparse($filepath, qr/\.[^.]*$/); 
my $filename = $basename . $extension; 

Bạn có thể kiểm tra kết quả bằng những điều sau đây.

my @test_paths = (
    '/foo/bar/fish.wibble', 
    '/foo/bar/fish.', 
    '/foo/bar/fish.asdf.d', 
    '/foo/bar/fish.wibble.', 
    '/fish.wibble', 
    'fish.wibble', 
); 

foreach my $this_path (@test_paths) { 
    print "Current path: $this_path\n"; 
    my ($this_basename, $parentdir, $extension) = fileparse($this_path, qr/\.[^.]*$/); 
    my $this_filename = $this_basename . $extension; 

    foreach my $var (qw/$parentdir $this_filename $this_basename $extension/) { 
     print "$var = '" . eval($var) . "'\n"; 
    } 

    print "\n\n"; 
} 

Hy vọng điều này sẽ hữu ích.