Delphi 2010 có chức năng LoadTextFromFile không?

Question

Trong khi chuyển một số mã từ Delphi 7 sang Delphi 2010, tôi đã viết lại hàm LoadTextFromFile() của mình.

function LoadTextFromFile(const aFullFileName: string): string; 
var 
    lBuffer:  TBytes; 
    lEncoding: TEncoding; 
    lFileStream: TFileStream; 
    lSize:  Integer; 

begin 

    if not FileExists(aFullFileName) then 
    begin 
    raise Exception.Create('File "' + aFullFileName + '" not found.'); 
    end; 

    lFileStream := TFileStream.Create(aFullFileName, fmOpenRead + fmShareDenyNone); 
    try 

    if lFileStream.Size <= 0 then 
    begin 
     Result := ''; 
    end 
    else 
    begin 

     lSize := lFileStream.Size - lFileStream.Position; 

     SetLength(lBuffer, lSize); 

     // Read file into TBytes buffer 
     lFileStream.Read(lBuffer[0], lSize); 

     // Read encoding from buffer 
     TEncoding.GetBufferEncoding(lBuffer, lEncoding); 

     // Get string from buffer 
     Result := lEncoding.GetString(lBuffer); 

    end; 

    finally 
    lFileStream.Free; 
    end; 

end; 

Khi một ý nghĩ đánh vào đầu tôi: phải có thứ gì đó như thế này trong thư viện chuẩn. Nhiều người dùng muốn đọc một tệp văn bản thành một chuỗi, nhưng tôi không thể tìm thấy một hàm chuẩn như vậy. Gần nhất tôi đến là sử dụng TStringlist để tải văn bản. Nhưng A) tạo ra một TStringlist trông không cần thiết và B) Tôi không muốn bị chi phí từ TStringlist.

Câu hỏi: có chức năng LoadTextFromFile tiêu chuẩn trong Delphi 2010 không?

Answer 1

Có tồn tại một chức năng giống như vậy trong Delphi 2010, được gọi là ReadAllText và là một phần của bản ghi TFile được khai báo trong đơn vị IOUtils.

Kiểm tra khai

class function ReadAllText(const Path: string): string; overload; inline; static; 
class function ReadAllText(const Path: string; const Encoding: TEncoding): string; overload; inline; static; 

này xem mẫu này

program Project80; 

{$APPTYPE CONSOLE} 

uses 
    IOUtils, 
    SysUtils; 
Var 
Content : string; 
begin 
    try 
    Content:=TFile.ReadAllText('C:\Downloads\test.css'); //load the text of the file in a single line of code 
    //Content:=TFile.ReadAllText('C:\Downloads\test.css',TEncoding.UTF8); //you can an encoding too. 
    Writeln(Content); 
    Readln; 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

Answer 2

TStringStream.LoadFromStream/file? Dù sao dây rất lớn luôn luôn là một chút lãng phí. Bạn phải rất cẩn thận để không vô tình sao chép nó.

Answer 3

Một cách nhanh chóng là TStringList.LoadFromFile(). Sau đó sử dụng TStringlist.Text để truy cập dữ liệu dưới dạng một chuỗi lớn. Đừng quên tạo/miễn phí, lý tưởng nhất là sử dụng try..finally block.

Answer 4

Tôi đã thử giải pháp tương tự, nhưng đã biến lEncoding biến lớp thành liên tục, vì vậy tôi sẽ lưu tệp của mình vào cùng một mã hóa như tôi đã đọc. Tuy nhiên, cuộc gọi đến GetBufferEncoding sẽ không thành công nếu lEncoding đã được đặt thành thứ gì đó (vì nó sẽ là nếu tệp trước đó được đọc). Vì vậy, trước tiên, tôi đã cố gắng giải phóng nó và điều đó đã gây ra các vi phạm truy cập khắp nơi. Bây giờ tôi chỉ cần thiết lập nó để nil trước khi thực hiện cuộc gọi thứ hai và nó có vẻ làm việc.

Something như thế này:

if Assigned(lEncoding) then begin 
    lEncoding := nil; 
end; 
GetBufferedEncoding(buffer, lEncoding);