Có chức năng chuẩn Delphi nào để thoát HTML không?

Question

Tôi đã có một báo cáo có nghĩa vụ phải kiểm soát lưới và tạo ra đầu ra HTML. Một trong các cột trong lưới có thể hiển thị bất kỳ số lượng giá trị nào hoặc <Any>. Khi điều này được đầu ra cho HTML, tất nhiên, nó kết thúc lên trống.

Tôi có thể viết một số thường lệ để sử dụng StringReplace để biến thành <Any> để nó hiển thị đúng trường hợp cụ thể này, nhưng tôi có lẽ có một trong RTL ở đâu đó đã được kiểm tra và làm đúng. Bất cứ ai biết nơi tôi có thể tìm thấy nó?

Answer 1

Tôi chắc chắn 99% rằng chức năng như vậy không tồn tại trong RTL (như của Delphi 2009). Tất nhiên - tuy nhiên - nó là tầm thường để viết một hàm như vậy.

Cập nhật

HTTPUtil.HTMLEscape là những gì bạn đang tìm kiếm:

function HTMLEscape(const Str: string): string; 

Tôi không dám công bố mã ở đây (vi phạm bản quyền, có lẽ), nhưng thói quen rất đơn giản. Nó mã hóa "<", ">", "&", và """ để <, >, & và ". Nó cũng thay thế ký tự # 92, # 160 .. # 255 vào thập phân mã, ví dụ như \.

bước sau này là không cần thiết nếu các tập tin là UTF-8, và cũng vô lý, bởi vì ký tự đặc biệt cao hơn, chẳng hạn như ∮ được trái như họ đang có, trong khi ký tự đặc biệt thấp hơn, chẳng hạn như ×, được mã hóa.

Cập nhật 2

Để trả lời câu trả lời của Stijn Sanders, tôi đã thực hiện một bài kiểm tra hiệu năng đơn giản.

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Windows, SysUtils; 

var 
    t1, t2, t3, t4: Int64; 
    i: Integer; 
    str: string; 
const 
    N = 100000; 


function HTMLEncode(const Data: string): string; 
var 
    i: Integer; 
begin 

    result := ''; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': result := result + '&lt;'; 
     '>': result := result + '&gt;'; 
     '&': result := result + '&amp;'; 
     '"': result := result + '&quot;'; 
    else 
     result := result + Data[i]; 
    end; 

end; 

function HTMLEncode2(Data: string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&amp;',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]); 
end; 

begin 

    QueryPerformanceCounter(t1); 
    for i := 0 to N - 1 do 
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t2); 

    QueryPerformanceCounter(t3); 
    for i := 0 to N - 1 do 
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t4); 

    Writeln(IntToStr(t2-t1)); 
    Writeln(IntToStr(t4-t3)); 

    Readln; 


end. 

Đầu ra là

532031 
801969 

Answer 2

Tôi thường chỉ cần sử dụng mã này:

function HTMLEncode(Data:string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]), 
     #13#10,'<br />'#13#10,[rfReplaceAll]); 
end; 

(bản quyền nó open source?)

Answer 3

Có vẻ như đây là một cuộc thi nhỏ :) Dưới đây là một triển khai khác:

function HTMLEncode3(const Data: string): string; 
var 
    iPos, i: Integer; 

    procedure Encode(const AStr: String); 
    begin 
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char)); 
    Inc(iPos, Length(AStr)); 
    end; 

begin 
    SetLength(result, Length(Data) * 6); 
    iPos := 1; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': Encode('&lt;'); 
     '>': Encode('&gt;'); 
     '&': Encode('&amp;'); 
     '"': Encode('&quot;'); 
    else 
     result[iPos] := Data[i]; 
     Inc(iPos); 
    end; 
    SetLength(result, iPos - 1); 
end; 

Cập nhật 1: Cập nhật ban đầu đã cung cấp mã không chính xác.

Cập nhật 2: Và lần:

HTMLEncode : 2286508597 
HTMLEncode2: 3577001647 
HTMLEncode3: 361039770 

Answer 4

Unit HTTPApp có một chức năng gọi là HTMLEncode. Nó cũng có các chức năng liên quan đến HTML/HTTP khác.

Answer 5

thế nào về cách mà thay thế ký tự đặc biệt:

function HtmlWeg(sS: String): String; 
var 
    ix,cc: Integer; 
    sC, sR: String; 
begin 
    result := sS; 
    ix := pos('\u00',sS); 

    while ix >0 do 
    begin 
    sc := copy(sS,ix+4,2) ; 
    cc := StrtoIntdef('$' +sC,32); 
    sR := '' + chr(cc); 
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ; 
    ix := pos('\u00',sS); 
    end; 
    result := sS; 
end; 

Answer 6

chức năng của tôi kết hợp cho vòng lặp với việc tái phân bổ tối thiểu của chuỗi:

function HtmlEncode(const Value: string): string; 
var 
    i: Integer; 

begin 
    Result := Value; 
    i := 1; 

    while i <= Length(Result) do 
    begin 
    if Result[i] = '<' then 
    begin 
     Result[i] := '&'; 
     Insert('lt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '>' then 
    begin 
     Result[i] := '&'; 
     Insert('gt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '"' then 
    begin 
     Result[i] := '&'; 
     Insert('quot;', Result, i + 1); 
     Inc(i, 6); 
    end 
    else if Result[i] = '&' then 
    begin 
     Insert('amp;', Result, i + 1); 
     Inc(i, 5); 
    end 
    else 
     Inc(i); 
    end; 
end; 

Answer 7

Tôi không biết trong đó delphi phiên bản nó đã được giới thiệu nhưng, có đơn vị System.NetEncoding có:

TNetEncoding.HTML.Encode 
TNetEncoding.HTML.Decode 

f unctions. Đọc lên here. Bạn không cần thư viện bên ngoài nữa.