Chuyển chuỗi mảng thành mảng int

Question

Tôi đã thử một vài cách khác nhau và dường như không nhận được kết quả tôi muốn bằng cách sử dụng vb.net.

Tôi có một chuỗi các chuỗi. { "55555", "44.444", " "}

Tôi cần một mảng các số nguyên {} 55555,44444

Đây là một trang WPF đang gửi các mảng như một tham số để báo cáo tinh thể.

Mọi trợ giúp đều được đánh giá cao.

Answer 1

Bạn có thể sử dụng List(Of T).ConvertAll phương pháp:

Dim stringList = {"123", "456", "789"}.ToList 
Dim intList = stringList.ConvertAll(Function(str) Int32.Parse(str)) 

hoặc với các đại biểu

Dim intList = stringList.ConvertAll(AddressOf Int32.Parse) 

Nếu bạn chỉ muốn sử dụng Mảng, bạn có thể sử dụng Array.ConvertAll method:

Dim stringArray = {"123", "456", "789"} 
Dim intArray = Array.ConvertAll(stringArray, Function(str) Int32.Parse(str)) 

Ồ, tôi đã bỏ lỡ chuỗi trống trong dữ liệu mẫu của bạn. Sau đó, bạn cần phải kiểm tra này:

Dim value As Int32 
Dim intArray = (From str In stringArray 
       Let isInt = Int32.TryParse(str, value) 
       Where isInt 
       Select Int32.Parse(str)).ToArray 

Bằng cách này, đây là như nhau trong cú pháp phương pháp, xấu xí as always in VB.NET:

Dim intArray = Array.ConvertAll(stringArray, 
         Function(str) New With { 
          .IsInt = Int32.TryParse(str, value), 
          .Value = value 
         }).Where(Function(result) result.IsInt). 
       Select(Function(result) result.Value).ToArray 

Answer 2

Có lẽ một cái gì đó như thế này:

dim ls as new List(of string)() 
ls.Add("55555") 
ls.Add("44444") 
ls.Add(" ") 
Dim temp as integer 
Dim ls2 as List(Of integer)=ls.Where(function(x) integer.TryParse(x,temp)).Select(function(x) temp).ToList() 

Answer 3

Bạn có thể sử dụng phương pháp Array.ConvertAll:

Dim arrStrings() As String = {"55555", "44444"} 
    Dim arrIntegers() As Integer = Array.ConvertAll(arrStrings, New Converter(Of String, Integer)(AddressOf ConvertToInteger)) 


    Public Function ConvertToInteger(ByVal input As String) As Integer 
     Dim output As Integer = 0 

     Integer.TryParse(input, output) 

     Return output 
    End Function 

Answer 4

Có thể thêm một vài dòng mã so với các câu trả lời khác nhưng ...

'Example assumes the numbers you are working with are all Integers. 
    Dim arrNumeric() As Integer 

    For Each strItemInArray In YourArrayName 

     If IsNumeric(strItemInArray) Then 

      If arrNumeric Is Nothing Then 

       ReDim arrNumeric(0) 
       arrNumeric(0) = CInt(strItemInArray) 

      Else 

       ReDim Preserve arrNumeric(arrNumeric.Length) 
       arrNumeric(arrNumeric.Length - 1) = CInt(strItemInArray) 

      End If 

     End If 

    Next 

Answer 5

My $ .02

Dim stringList() As String = New String() {"", "123", "456", "789", "a"} 
    Dim intList() As Integer 

    intList = (From str As String In stringList 
       Where Integer.TryParse(str, Nothing) 
       Select (Integer.Parse(str))).ToArray