Capture chuỗi thay thế regex

Question

Từ những gì tôi có thể thu thập từ các tài liệu Pharo trên regex, tôi có thể xác định một đối tượng biểu hiện thường xuyên như:

re := '(foo|re)bar' asRegex 

Và tôi có thể thay thế các regex phù hợp với một chuỗi qua này:

re copy: 'foobar blah rebar' replacingMatchesWith: 'meh' 

Điều này sẽ dẫn đến: `'meh blah meh'.

Cho đến nay, rất tốt. Nhưng tôi muốn thay thế 'bar' và để lại tiền tố một mình. Do đó, tôi cần một biến để xử lý parenthetical được chụp:

re copy: 'foobar blah rebar' replacingMatchesWith: '%1meh' 

Và tôi muốn có kết quả: 'foomeh blah remeh'. Tuy nhiên, điều này chỉ mang lại cho tôi: '%1meh blah %1meh'. Tôi cũng đã thử sử dụng \1 hoặc \\1 hoặc $1 hoặc {1} và nhận thay thế chuỗi chữ, ví dụ:, '\1meh blah \1meh' là kết quả.

tôi có thể làm điều này một cách dễ dàng đủ trong GNU Smalltalk với:

'foobar blah rebar' replacingAllRegex: '(foo|re)bar' with: '%1meh' 

Nhưng tôi không thể tìm thấy bất cứ nơi nào trong tài liệu regex Pharo mà nói với tôi làm thế nào tôi có thể làm điều này trong Pharo. Tôi đã thực hiện một loạt các googling cho Pharo regex là tốt, nhưng không bật lên bất cứ điều gì. Đây có phải là phần khả năng của lớp RxMatcher hay một số lớp Pharo regex khác không?

Answer 1

Sau khi thử nghiệm một chút với lớp RxMatcher, tôi đã thay đổi sau vào RxMatcher#copyStream:to:replacingMatchesWith: selector:

copyStream: aStream to: writeStream replacingMatchesWith: aString 
    "Copy the contents of <aStream> on the <writeStream>, 
    except for the matches. Replace each match with <aString>." 

    | searchStart matchStart matchEnd | 
    stream := aStream. 
    markerPositions := nil. 
    [searchStart := aStream position. 
    self proceedSearchingStream: aStream] whileTrue: [ | ws rep | 
     matchStart := (self subBeginning: 1) first. 
     matchEnd := (self subEnd: 1) first. 
     aStream position: searchStart. 
     searchStart to: matchStart - 1 do: 
      [:ignoredPos | writeStream nextPut: aStream next]. 

     "------- The following lines replaced: writeStream nextPutAll: aString ------" 
     "Do the regex replacement including lookback substitutions" 
     writeStream nextPutAll: (aString format: self subexpressionStrings). 
     "-------" 

     aStream position: matchEnd. 
     "Be extra careful about successful matches which consume no input. 
     After those, make sure to advance or finish if already at end." 
     matchEnd = searchStart ifTrue: 
      [aStream atEnd 
       ifTrue: [^self "rest after end of whileTrue: block is a no-op if atEnd"] 
       ifFalse: [writeStream nextPut: aStream next]]]. 
    aStream position: searchStart. 
    [aStream atEnd] whileFalse: [writeStream nextPut: aStream next] 

Và sau đó "tiếp cận" mục:

subexpressionStrings 
    "Create an array of lookback strings" 
    | ws | 
    ws := Array new writeStream. 
    2 to: (self subexpressionCount) do: [ :n | | se | 
     ws nextPut: ((se := self subexpression: n) ifNil: [ '' ] ifNotNil: [ se ]) ]. 
    ^ws contents. 

Với sửa đổi này, tôi có thể thực hiện tìm kiếm trong chuỗi thay thế bằng cách sử dụng mẫu Smalltalk String#format: cho đối số:

re := '((foo|re)ba(r|m))' asRegex 
re copy: 'foobar meh rebam' replacingMatchesWith: '{2}bu{3} (was {1})' 

Kết quả trong:

'foobur (was foobar) meh rebum (was rebam)' 

Answer 2

Bạn đã kiểm tra trợ giúp Regex chưa? Không có #replacingAllRegex:, nhưng các khớp có #subexpression: