Trong Mathematica, chức năng nội suy nào là ListPlot sử dụng?

Question

[Ảnh chụp màn hình bên dưới]

Tôi đã sử dụng ListPlot để vẽ một đường trơn thông qua một số điểm dữ liệu. Nhưng tôi muốn có thể làm việc với đạo hàm thứ nhất và thứ 2 của cốt truyện, vì vậy tôi nghĩ tôi sẽ tạo ra một "hàm" thực tế bằng cách sử dụng Interpolation. Nhưng như bạn thấy trong hình, nó không trơn tru. Có một số gai lạ khi tôi làm Lô [Nội suy [...] ...]. Tôi tự hỏi làm thế nào ListPlot có được chức năng nội suy của nó, và làm thế nào tôi có thể nhận được cùng một điều, bằng cách sử dụng Interpolation [] hoặc một số phương pháp khác.

cảm ơn,
Rob

Dưới đây là một số văn bản cho sao chép/dán:

myPoints = {{0.,3.87},{1.21,4.05},{2.6,4.25},{4.62,4.48},{7.24,4.73},{9.66,4.93}, 
{12.48,5.14},{14.87,5.33},{17.34,5.55},{19.31,5.78},{20.78,6.01},{22.08,6.34}, 
{22.82,6.7},{23.2,7.06},{23.41,7.54},{23.52,8.78},{23.59,9.59},{23.62,9.93}, 
{23.72,10.24},{23.88,10.56},{24.14,10.85},{24.46,11.05},{24.81,11.2}, 
{25.73,11.44},{27.15,11.63}} 

ListPlot[myPoints, Joined -> True, Mesh -> Full] 

Plot[Interpolation[myPoints][x], {x, 0, 27.2}] 

Người cuối cùng có gai.

Chỉnh sửa ...

Gleno pointed out that my List plot is linear. But what about when both have 
InterpolationOrder -> 3? 
ListPlot[myPoints, Joined -> True, Mesh -> Full, InterpolationOrder -> 3] 
Plot[Interpolation[myPoints, InterpolationOrder -> 3][x], {x, 0, 27.2}] 

Answer 1

Tôi tin rằng phương pháp được sử dụng bởi ListPlot cho phép nội suy là suy từng phối hợp như một chức năng của chỉ số danh sách. Một cái gì đó như sau trông rất giống đầu ra từ ListPlot[...,InterpolationOrder->3]:

With[{ 
    xyInterpolation=Interpolation[#,InterpolationOrder->3]&/@Transpose[myPoints]}, 
    ParametricPlot[Through[xyInterpolation[i]],{i,1,Length[myPoints]}] 
] 

Từ một suy như vậy, bạn sẽ có thể lấy các dẫn xuất của mình thông qua sự khác biệt tiềm ẩn, ví dụ dx/dy == (dx/dt)/(dy/dt). Một thỏa thích phô trương ký hiệu rằng ở một nơi mà nó có thể làm cho một số nhà toán học puke :)

Answer 2

Xin lỗi vì đã dissapoint bạn, nhưng câu trả lời là rất đơn giản. ListLinePlot/ListPlot chỉ vẽ một đường thẳng

Plot[Interpolation[myPoints, InterpolationOrder -> 1][x], {x, 0, 27.2}] 

sản xuất dòng un-hacky cùng. Bạn cũng có thể có sự khác biệt về thành công khi áp dụng phép nội suy bậc hai và sử dụng Splines.

Plot[Interpolation[myPoints, InterpolationOrder -> 2, Method -> "Spline"][x], {x, 0, 27.2}] 

Answer 3

lẽ dễ dàng hơn:

interp = Interpolation[myPoints, InterpolationOrder -> 2, Method -> "Spline"] 

(*Now let's plot the function and its derivative*) 
Show[ListPlot@myPoints, 
    Plot[{interp'[x], interp[x]}, 
      {x, Min[First /@ myPoints], Max[First /@ myPoints]}, PlotRange -> All]] 

Trong "khu vực quan tâm":

Show[Plot[{interp'[x], interp[x]}, {x, 23, 24}], ListPlot@myPoints] 

Nếu bạn muốn liên tục thứ hai phái sinh, chỉ cần tăng thứ tự nội suy như thế này:

interp = Interpolation[myPoints, InterpolationOrder -> 3, Method -> "Spline"]; 
Show[Plot[{interp'[x], interp[x]}, {x, 23, 24}], ListPlot@myPoints]