Mở tệp Excel để đọc với VBA mà không cần hiển thị

Question

Tôi muốn tìm kiếm qua các tệp Excel hiện có bằng macro, nhưng tôi không muốn hiển thị các tệp đó khi chúng được mở bằng mã. Có cách nào để họ mở "trong nền" không?

Answer 1

Không chắc chắn nếu bạn có thể mở chúng vô hình trong hiện tại xuất sắc dụ

Bạn có thể mở một trường hợp mới của excel mặc dù, che giấu nó và sau đó mở workbook

Dim app as New Excel.Application 
app.Visible = False 'Visible is False by default, so this isn't necessary 
Dim book As Excel.Workbook 
Set book = app.Workbooks.Add(fileName) 
' 
' Do what you have to do 
' 
book.Close SaveChanges:=False 
app.Quit 
Set app = Nothing 

Như những người khác đã được đăng, đảm bảo bạn dọn dẹp sau khi bạn hoàn tất bất kỳ sổ làm việc nào đã mở

Answer 2

Làm nổi bật, ẩn sổ làm việc và lưu chúng dưới dạng ẩn. Khi ứng dụng của bạn tải chúng, chúng sẽ không được hiển thị.

Chỉnh sửa: khi đọc lại, nó trở nên rõ ràng rằng các sổ làm việc này không phải là một phần của ứng dụng của bạn. Giải pháp như vậy sẽ không phù hợp với sổ làm việc của người dùng.

Answer 3

Mở chúng từ phiên bản Excel mới.

Sub Test() 

    Dim xl As Excel.Application 
    Set xl = CreateObject("Excel.Application") 

    Dim w As Workbook 
    Set w = xl.Workbooks.Add() 

    MsgBox "Not visible yet..." 
    xl.Visible = True 

    w.Close False 
    Set xl = Nothing 

End Sub 

Bạn cần phải nhớ dọn dẹp sau khi hoàn tất.

Answer 4

Nếu phù hợp với nhu cầu của bạn, tôi sẽ chỉ cần sử dụng

Application.ScreenUpdating = False 

với lợi ích bổ sung tăng tốc mã của bạn, chứ không chậm nó xuống bằng cách sử dụng một trường hợp thứ hai của Excel.

Answer 5

Mặc dù bạn có câu trả lời cho những người tìm thấy câu hỏi này, bạn cũng có thể mở bảng tính Excel dưới dạng kho dữ liệu JET. Mượn chuỗi kết nối từ một dự án tôi đã sử dụng nó trên, nó sẽ trông giống như thế này:

strExcelConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & objFile.Path & ";Extended Properties=""Excel 8.0;HDR=Yes""" 
strSQL = "SELECT * FROM [RegistrationList$] ORDER BY DateToRegister DESC" 

Lưu ý rằng "RegistrationList" là tên của tab trong sổ làm việc. Có một vài hướng dẫn nổi trên web với các thông tin cụ thể về những gì bạn có thể và không thể truy cập một trang tính theo cách này.

Chỉ nghĩ rằng tôi muốn thêm. :)

Answer 6

Để mở một bảng tính như ẩn trong trường hợp hiện tại của Excel, sử dụng như sau:

Application.ScreenUpdating = False 
    Workbooks.Open Filename:=FilePath, UpdateLinks:=True, ReadOnly:=True 
    ActiveWindow.Visible = False 
    ThisWorkbook.Activate 
    Application.ScreenUpdating = True 

Answer 7

Mở workbook như ẩn và sau đó đặt nó là "lưu" để người dùng không được nhắc nhở khi họ đóng cửa.

Dim w As Workbooks 

Private Sub Workbook_Open() 
    Application.ScreenUpdating = False 
    Set w = Workbooks 
    w.Open Filename:="\\server\PriceList.xlsx", UpdateLinks:=False, ReadOnly:=True 'this is the data file were going to be opening 
    ActiveWindow.Visible = False 
    ThisWorkbook.Activate 
    Application.ScreenUpdating = True 
End Sub 

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    w.Item(2).Saved = True 'this will suppress the safe prompt for the data file only 
End Sub 

Điều này phần nào dẫn xuất câu trả lời do Ashok đăng.

Bằng cách thực hiện theo cách này, bạn sẽ không được nhắc lưu thay đổi vào tệp Excel mà bạn đọc. Điều này thật tuyệt vời nếu tệp Excel mà bạn đọc được dự định là nguồn dữ liệu để xác thực. Ví dụ: nếu sổ làm việc chứa tên sản phẩm và dữ liệu giá, nó có thể bị ẩn và bạn có thể hiển thị tệp Excel đại diện cho hóa đơn có các trình đơn thả xuống cho sản phẩm xác thực từ danh sách giá đó.

Sau đó, bạn có thể lưu trữ danh sách giá trên một vị trí được chia sẻ trên mạng ở đâu đó và đặt ở chế độ chỉ đọc.

Answer 8

Vấn đề với cả câu trả lời của iDevlop và Ashok là vấn đề cơ bản là lỗ hổng thiết kế Excel (rõ ràng) trong đó phương thức Open không tuân theo cài đặt Application.ScreenUpdating của False. Do đó, đặt nó thành False là không có lợi cho vấn đề này.

Nếu giải pháp Patrick McDonald quá nặng nề do phí bắt đầu phiên bản Excel thứ hai, thì giải pháp tốt nhất tôi tìm được là giảm thiểu thời gian mở sổ làm việc bằng cách kích hoạt lại cửa sổ gốc nhanh càng tốt:

Dim TempWkBk As Workbook 
Dim CurrentWin As Window 

Set CurrentWin = ActiveWindow 
Set TempWkBk = Workbooks.Open(SomeFilePath) 
CurrentWin.Activate  'Allows only a VERY brief flash of the opened workbook 
TempWkBk.Windows(1).Visible = False 'Only necessary if you also need to prevent 
            'the user from manually accessing the opened 
            'workbook before it is closed. 

'Operate on the new workbook, which is not visible to the user, then close it... 

Answer 9

Một cách tiếp cận đơn giản hơn nhiều mà không liên quan đến thao tác cửa sổ đang hoạt động:

Dim wb As Workbook 
Set wb = Workbooks.Open("workbook.xlsx") 
wb.Windows(1).Visible = False 

Từ những gì tôi có thể nói chỉ số windows trên bảng tính nên luôn luôn 1. Nếu bất cứ ai biết về bất kỳ điều kiện chủng tộc nào có thể làm cho điều này không đúng sự thật, hãy cho tôi biết.