Lô, mặt phẳng, điểm, đường thẳng, hình cầu trong cùng một ô 3D. Nhiều số liệu trong cùng một lô trong Mathematica

Question

Làm thế nào để vẽ đồ thị ví dụ một mặt phẳng và một đường thẳng trong cùng một ô 3D?

Answer 1

Show và Plot3D có thể xử lý. Có lẽ có nhiều cách khác.

l = Line[{{-2, -2, 41}, {6, 4, -10}}]; 

Show[{Plot3D[{2 x + 7 y}, {x, -2, 5}, {y, -2, 5}, AxesLabel -> {x, y, z}], 
     Graphics3D[{Thick, l}]}] 

Answer 2

Chỉ cần khoe:

Manipulate[ 

Show[ 
    {Plot3D[ {1}, {x, -1, 1}, {y, -1, 1}, PlotRange -> {-1, 1}, Mesh -> False], 
    Plot3D[{-1}, {x, -1, 1}, {y, -1, 1},      Mesh -> False], 
    ParametricPlot3D[{{Sin@t, Cos@t, 1}, {Sin@t, Cos@t, -1}}, {t, 0, 2 Pi}], 
    Graphics3D[ 
    {Table[{Hue[n/10], Thick, Line[{{Re[#], Im[#], 1}, {-z Re[#], -z Im[#], z}}&@ 
     Exp[n 2 I Pi/10]]}, {n, 10}], 
    Sphere[{0, 0, 0}, .3]}]}], 
    {z, 1, -1}] 

Answer 3

tôi không thể cưỡng lại một trong hai ...

GraphicsGrid[ 
{ 
    {ContourPlot3D[x + 2 y + 3 z , {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
    Contours -> {0}, Axes -> None, ColorFunction -> (White &), 
    Lighting -> "Neutral"], 
    Style["One plane", FontFamily -> "Comic Sans MS", 36, Bold]}, 
    {ContourPlot3D[x + 2 y + 3 z , {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
    Contours -> {0, 5}, Axes -> None, ColorFunction -> (Green &), 
    Lighting -> "Neutral"], 
    Style["Two plane", FontFamily -> "Comic Sans MS", 36, Bold]}, 
    {ContourPlot3D[x + 2 y + 3 z , {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
    Contours -> {0}, Axes -> None, ColorFunction -> (Red &), 
    Lighting -> "Neutral"], 
    Style["Red plane", FontFamily -> "Comic Sans MS", 36, Bold]}, 
    {Show[ 
    ContourPlot3D[x + 2 y + 3 z , {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
    Contours -> {0}, Axes -> None, ColorFunction -> (Blue &), 
    Lighting -> "Neutral"], 
    Graphics3D[{Orange, Thickness[0.01], 
     Line[{{-2, -2, -2}, {2, 2, 2}}]}] 
    ], Style["Blue plane", FontFamily -> "Comic Sans MS", 36, Bold]} 
    } 
]