biểu đồ không có đường thẳng đứng trong Mathematica

Question

Tôi đang cố tạo biểu đồ không có đường thẳng đứng. Tôi muốn có một âm mưu trông giống như một chức năng. Như thế này:

Cùng một câu hỏi đã được hỏi cho R trước (histogram without vertical lines) nhưng tôi trên Mathematica.

Tôi đã xem xét các tùy chọn ChartStyle mà không thành công.

Answer 1

Có thể có nhiều cách để thực hiện điều này bằng cách nghịch ngợm với EdgeForm[] và FaceForm[] trong Histogram, nhưng tôi thấy đơn giản hơn khi tự cuộn, bất cứ khi nào tôi cần. Dưới đây là một rất đơn giản và nhanh chóng dụ:

histPlot[data_, bins_, color_: Blue] := Module[{ 
     countBorder = 
    Partition[Riffle[Riffle[#1, #1[[2 ;;]]], Riffle[#2, #2]], 2] & @@ 
    HistogramList[data, bins, "PDF"] 
    }, 
    ListLinePlot[countBorder, PlotStyle -> color] 
    ] 

Làm histPlot[RandomReal[NormalDistribution[],{1000}],{-3,3,0.1}] mang đến cho

Sau đó bạn có thể mở rộng này thực hiện bất kỳ lựa chọn thay vì chỉ "PDF", và đối với trường hợp khi bạn muốn chọn thùng tự động. Tôi không thích tự động binning, bởi vì tôi muốn kiểm soát chiều rộng và chiều rộng bin của tôi để dự đoán và so sánh dễ dàng so với các lô khác.

Answer 2

Bạn cũng có thể sử dụng ListPlot với InterpolationOrder->0:

(* example data *) 
data = RandomVariate[NormalDistribution[], 10^3]; 

hist = HistogramList[data, {.5}]; 

ListPlot[Transpose[{hist[[1]], ArrayPad[hist[[2]], {0, 1}, "Fixed"]}], 
    InterpolationOrder -> 0, 
    Joined -> True, 
    AxesOrigin -> {hist[[1, 1]], 0}] 

Answer 3

Dưới đây là hai phương pháp mà làm việc trong phiên bản 7, sử dụng sau xử lý:

rdat = RandomReal[NormalDistribution[0, 1], 200];

MapAt[ 
    {Blue, 
    Line[# /. {{Rectangle[{x_, y_}, {X_, Y_}]}} :> Sequence[{x, Y}, {X, Y}]] } &, 
    Histogram[rdat, PerformanceGoal -> "Speed"], 
    {1, 2, 2, 2} 
] 

Cases[ 
    Histogram[rdat, PerformanceGoal -> "Speed"], 
    Rectangle[{x_, y_}, {X_, Y_}] :> {{x, Y}, {X, Y}}, 
    \[Infinity] 
]; 

Graphics[Line[Join @@ %], AspectRatio -> 1/GoldenRatio, Axes -> True]