AsyncCall với Delphi 2007

Question

Điều cơ bản tôi muốn là bắt đầu AsyncCall và tiếp tục tải mã của tôi. Tôi có phần giao diện tiêu thụ rất nhiều thời gian (600 + ms) và tôi muốn tải mã này trong chuỗi độc lập.

Tôi đã cố gắng sử dụng AsyncCall để làm một cái gì đó như thế này:

procedure Load; 
begin 
... 
end; 

initialization 
    AsyncCall(@Load, []); // or LocalAsyncCall(@Load) 

Tuy nhiên, thủ tục Load này thực sự bắt đầu trong chủ đề chính và không có trong các chủ đề đã tạo mới. Làm cách nào để buộc quy trình Load được tải trong bất kỳ chuỗi nào khác ngoài MainThread?

Tôi có thể tạo TThread và Execute điều này nhưng tôi muốn bắt buộc AsyncCall hoặc LocalAsyncCall hoặc bất kỳ thứ gì từ thư viện AsyncCall để hoạt động.

Cảm ơn sự giúp đỡ của bạn.

Answer 1

Sự cố là mã của bạn không giữ lại giao diện IAsyncCall được trả về bởi hàm AsyncCall.

AsyncCall(@Load, []); 
//AsyncCall returns an IAsyncCall interface, 
//but this code does not take a reference to it 

Do đó, giao diện được trả lại có số tham chiếu được giảm xuống 0 ngay khi phần khởi tạo hoàn tất. Điều này do đó giải phóng các đối tượng mà thực hiện các giao diện mà thực hiện điều này:

destructor TAsyncCall.Destroy; 
begin 
    if FCall <> nil then 
    begin 
    try 
--> FCall.Sync; // throw raised exceptions here 
    finally 
     FCall.Free; 
    end; 
    end; 
    inherited Destroy; 
end; 

Điểm mấu chốt là cuộc gọi đến Sync mà lực lượng các cuộc gọi không đồng bộ được thực hiện để hoàn thành. Tất cả điều này xảy ra trong chuỗi chính giải thích hành vi mà bạn báo cáo.

---

Giải pháp là bạn chỉ cần giữ giao diện IAsyncCall còn sống bằng cách lưu trữ nó trong một biến.

var 
    a: IAsyncCall; 

initialization 
    a := AsyncCall(@Load, []); 

Trong mã thực bạn cần phải đảm bảo rằng Load đã hoàn thành trước khi chạy bất kỳ mã đó là phụ thuộc vào Load. Khi chương trình của bạn đạt đến một điểm mà nó yêu cầu Load để được gọi thì phải gọi Sync trên giao diện IAsyncCall.

Vì vậy, bạn có thể viết nó như thế này.

unit MyUnit; 

interface 

procedure EnsureLoaded; 

implementation 

uses 
    AsyncCalls; 

.... 

procedure Load; 
begin 
    .... 
end; 

var 
    LoadAsyncCall: IAsyncCall; 

procedure EnsureLoaded; 
begin 
    LoadAsyncCall := nil;//this will effect a call to Sync 
end; 

initialization 
    LoadAsyncCall := AsyncCall(@Load, []); 

end. 

Gọi EnsureLoaded từ các đơn vị khác yêu cầu Load để chạy. Hoặc, cách khác, hãy gọi EnsureLoaded từ bất kỳ phương thức nào được xuất bởi MyUnit phụ thuộc vào Load khi chạy. Tùy chọn thứ hai có đóng gói tốt hơn nhiều.

Answer 2

Các bạn đã thử một cái gì đó như thế này ?:

procedure Load; 
begin 
    if GetCurrentThreadId <> MainThreadID then 
    Beep; 
end; 

var a: IAsyncCall; 

initialization 
    a := AsyncCall(@Load, []); 
    a.ForceDifferentThread; 

ForceDifferentThread() cho AsyncCalls rằng chức năng được phân công phải không được thực hiện trong thread hiện hành.