Làm cách nào để mở một URL bằng trình duyệt mặc định với các ứng dụng đa nền tảng FireMonkey?

Question

Thông thường, tôi sử dụng: ShellExecute(0, 'OPEN', PChar(edtURL.Text), '', '', SW_SHOWNORMAL);

Làm thế nào tôi có thể có hành vi tương tự (mở một liên kết trong trình duyệt mặc định), trên tất cả các nền tảng (Windows và OSX)?

Answer 1

Trong diễn đàn thảo luận FireMonkey tôi tìm thấy mã này cho một câu hỏi về NSWorkspace.URLForApplicationToOpenURL:

uses 
    Posix.Stdlib; 
.... 
    _system(PAnsiChar('open ' + ACommand)); 

(không thử nghiệm của tôi)

---

Cập nhật: Posix là không có sẵn trên Windows nên không thể viết giải pháp sử dụng cùng một cuộc gọi hệ điều hành trên tất cả các nền tảng. Tôi đề xuất chuyển mã như vậy trong đơn vị 'XPlatform' trung tâm có một số POSIX IFDEF, v.v.

Answer 2

Về câu trả lời của mjn, tôi đã viết đơn vị sau đây. Tôi đã thử nghiệm thành công nó trên Windows nhưng tôi không có một OSX để kiểm tra nó trên nền tảng này. Nếu ai đó có thể xác nhận nó hoạt động, tôi sẽ đánh giá cao.

unit fOpen; 

interface 

uses 
{$IFDEF MSWINDOWS} 
    Winapi.ShellAPI, Winapi.Windows; 
{$ENDIF MSWINDOWS} 
{$IFDEF POSIX} 
    Posix.Stdlib; 
{$ENDIF POSIX} 

type 
    TMisc = class 
    class procedure Open(sCommand: string); 
    end; 

implementation 

class procedure TMisc.Open(sCommand: string); 
begin 
{$IFDEF MSWINDOWS} 
    ShellExecute(0, 'OPEN', PChar(sCommand), '', '', SW_SHOWNORMAL); 
{$ENDIF MSWINDOWS} 
{$IFDEF POSIX} 
    _system(PAnsiChar('open ' + AnsiString(sCommand))); 
{$ENDIF POSIX} 
end; 

end. 

và tôi gọi nó là như thế này:

TMisc.Open('https://stackoverflow.com/questions/7443264/how-to-open-an-url-with-the-default-browser-with-firemonkey-cross-platform-applic'); 

Answer 3

Và bây giờ là một C++ phiên bản (OSX đang chưa được kiểm tra, cũng không chắc chắn về #def _POSIX):

#ifdef _Windows 
#include <Winapi.Windows.hpp> 
#endif // _Windows 
#ifdef _POSIX 
#include <Posix.Stdlib.h> 
#endif // _POSIX 

void OpenCommand(String _sCommand) 
{ 
    #ifdef _Windows 
    ShellExecute(0, _T("open"), _sCommand.c_str(), _T(""), _T(""), SW_SHOWNORMAL); 
    #endif // _Windows 
    #ifdef _POSIX 
    _system(AnsiString("open " + AnsiString(_sCommand)).c_str()); 
    #endif // _POSIX 
} 

Answer 4

XE2 C++ mã được thử nghiệm thành công (Windows 7 64 và OSX Lion), những cải tiến nhỏ. Whiler Thank của, nỗi đau đã qua :)

#include <fmx.h> 
// --------------------------------------------------------------------------- 
#ifdef _WIN32 
#include <shellapi.h> 
#endif// Windows 
#ifdef TARGET_OS_MAC 
#include <Posix.Stdlib.hpp> 
#endif // Mac 

void OpenCommand(String _sCommand) { 
    #ifdef _Windows 
    String open = "open"; 
    ShellExecute(0, open.w_str(), _sCommand.c_str(), NULL, NULL, SW_SHOWNORMAL); 
    #endif // Windows 

    #ifdef TARGET_OS_MAC 
    system(AnsiString("open " + AnsiString(_sCommand)).c_str()); 
    #endif // Mac 
} 

Answer 5

_system(PAnsiChar('open ' + AnsiString(sCommand))); 

không hoạt động nếu chuỗi URL (sCommand) bao gồm char dấu và (&), cần thiết phải xác định nhiều đối số trong chuỗi truy vấn.

URL được sử dụng để xóa. trình duyệt trong OSX (Safari) bị cắt ngắn vào lần xuất hiện đầu tiên của &.

Answer 6

Như @NicoBlu đã đề cập, giải pháp được chấp nhận dường như cắt ngắn URL sau lần xuất hiện đầu tiên của '&'. Đây là những gì làm việc cho tôi mà không cần cắt ngắn:

uses Macapi.AppKit, Macapi.Foundation, Macapi.Helpers; 

// ... 

procedure OpenLinkInDefaultBrowser(const Link: string); 
    var URL : NSURL; 
     Workspace : NSWorkspace; 
begin 
    URL := TNSURL.Wrap(TNSURL.OCClass.URLWithString(StrToNSStr(Link))); 
    Workspace := TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace); 
    Workspace.openURL(URL); 
end; 

Answer 7

LEncodedString : String; 

begin 
    LEncodedString := TIdURI.URLEncode('http://www.malcolmgroves.com'); 
    sharedApplication.openURL(StringToNSURL(LEncodedString)); 
end; 

Answer 8

Đối với tất cả các nền tảng (Windows, MacOS, iOS và Android), bạn có thể sử dụng đơn vị tôi đã viết cho my blog

unit u_urlOpen; 

interface 

uses 
    System.SysUtils, System.Types, System.UITypes, System.Classes, 
    System.Variants, 
{$IF Defined(IOS)} 
    macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS; 
{$ELSEIF Defined(ANDROID)} 
Androidapi.JNI.GraphicsContentViewText, 
    Androidapi.JNI.Net, 
    Androidapi.JNI.App, 
    Androidapi.helpers; 
{$ELSEIF Defined(MACOS)} 
Posix.Stdlib; 
{$ELSEIF Defined(MSWINDOWS)} 
Winapi.ShellAPI, Winapi.Windows; 
{$ENDIF} 

type 
    tUrlOpen = class 
    class procedure Open(URL: string); 
    end; 

implementation 

class procedure tUrlOpen.Open(URL: string); 
{$IF Defined(ANDROID)} 
var 
    Intent: JIntent; 
{$ENDIF} 
begin 
{$IF Defined(ANDROID)} 
    Intent := TJIntent.Create; 
    Intent.setAction(TJIntent.JavaClass.ACTION_VIEW); 
    Intent.setData(StrToJURI(URL)); 
    tandroidhelper.Activity.startActivity(Intent); 
    // SharedActivity.startActivity(Intent); 
{$ELSEIF Defined(MSWINDOWS)} 
    ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL); 
{$ELSEIF Defined(IOS)} 
    SharedApplication.OpenURL(StrToNSUrl(URL)); 
{$ELSEIF Defined(MACOS)} 
    _system(PAnsiChar('open ' + AnsiString(URL))); 
{$ENDIF} 
end; 

end.