VBScript: Làm thế nào để làm mất một đối tượng từ điển được trả về từ một hàm?

Question

Tôi đang cố gắng trả về một từ điển từ một hàm. Tôi tin rằng chức năng này hoạt động chính xác, nhưng tôi không chắc cách sử dụng từ điển được trả về.

Dưới đây là phần có liên quan về chức năng của tôi:

Function GetSomeStuff() 
    ' 
    ' Get a recordset... 
    ' 

    Dim stuff 
    Set stuff = CreateObject("Scripting.Dictionary") 
    rs.MoveFirst 
    Do Until rs.EOF 
    stuff.Add rs.Fields("FieldA").Value, rs.Fields("FieldB").Value 
    rs.MoveNext 
    Loop 

    GetSomeStuff = stuff 
End Function 

Làm thế nào để gọi chức năng này và sử dụng từ điển trở lại?

EDIT: Tôi đã thử điều này:

Dim someStuff 
someStuff = GetSomeStuff 

và

Dim someStuff 
Set someStuff = GetSomeStuff 

Khi tôi cố gắng truy cập vào someStuff, tôi nhận được một lỗi:

Microsoft VBScript runtime error: Object required: 'GetSomeStuff' 

EDIT 2: Đang cố gắng chức năng này trong hàm:

Set GetSomeStuff = stuff 

Kết quả trong lỗi này:

Microsoft VBScript runtime error: Wrong number of arguments or invalid property assignment. 

Answer 1

Tôi không quá chắc chắn về vấn đề của bạn, vì vậy tôi đã thử nghiệm một chút.

Dường như bạn chỉ bỏ lỡ đó để gán một tham chiếu đến một đối tượng, bạn phải sử dụng set, ngay cả đối với một giá trị trả về:

Function GetSomeStuff 
    Dim stuff 
    Set stuff = CreateObject("Scripting.Dictionary") 
    stuff.Add "A", "Anaconda" 
    stuff.Add "B", "Boa" 
    stuff.Add "C", "Cobra" 

    Set GetSomeStuff = stuff 
End Function 

Set d = GetSomeStuff 
Wscript.Echo d.Item("A") 
Wscript.Echo d.Exists("B") 
items = d.Items 
For i = 0 To UBound(items) 
    Wscript.Echo items(i) 
Next 

Answer 2

Các bạn đã thử:

Dim returnedStuff 
Set returnedStuff = GetSomeStuff() 

Sau đó, "Đối với mỗi" iterating trên từ điển? Có một ví dụ về cách sử dụng từ điển (mặc dù cho VB6, ý chính của nó là như nhau mặc dù!) here.

Answer 3

Bạn đã thử thực hiện
set GetSomeStuff = stuff
trong dòng cuối cùng của hàm?