Có cách nào "chuẩn" để sử dụng tính tương đương của Reader và chức năng bình thường không?

Question

Tôi đang viết một khuôn khổ, trong đó chức năng chính hỏi người dùng về chức năng loại a -> [b].

Tuy nhiên, bởi vì chức năng đó có thể khá phức tạp, thực hiện của nó có thể thường trông như thế này:

fn a = extractPartOfAAndConvert a ++ extractAnotherPartofAAndConvert a 

Đó là lý do tại sao tôi figured sử dụng Reader có thể là một, ý tưởng thành ngữ tốt đẹp để đấu tranh đó. Tuy nhiên, đồng thời tôi nhận ra rằng một số người có thể không muốn sử dụng một đơn nguyên.

Trong khi thử nghiệm, tôi đã chế tác giải pháp này:

class Iso a b where 
    isoFrom :: a -> b 
    isoTo :: b -> a 

instance Iso a a where 
    isoFrom = id 
    isoTo = id 

instance Iso (a -> b) (Reader a b) where 
    isoFrom f = reader f 
    isoTo m = runReader m 

do đó cho phép tôi làm:

testCallback :: MyState -> Callback -> MyState 
testCallback myState cb = cb myState 

-- The important signature 
testCallbackGeneric :: Iso Callback a => MyState -> a -> MyState 
testCallbackGeneric myState cb = (isoTo cb) myState 

callbackFunction :: Callback 
callbackFunction s = s + 10 

callbackMonad :: Reader MyState MyState 
callbackMonad = do 
    x <- ask 
    return $ x - 10 

----------- 

let myStateA = testCallback myState callbackFunction 
-- let myStateB = testCallback myState callbackMonad -- won't work, obviously 
let myStateC = testCallbackGeneric myState callbackFunction 
let myStateD = testCallbackGeneric myState callbackMonad 

Tuy nhiên, tôi cảm thấy rất giống tôi reinventing the wheel.

Có cách nào để thể hiện sự tương đương của Reader để dễ dàng viết các chức năng chung như vậy mà không cần phải tạo lớp của riêng mình không?

Answer 1

Bạn chỉ có thể sử dụng thực tế là đơn vị chức năng (->) r đã có một phiên bản cho MonadReader r được xác định trong Control.Monad.Reader. Bạn có thể viết các chức năng sử dụng chỉ là MonadReader hạn chế và sử dụng chúng hoặc như các chức năng bình thường hoặc trong ReaderT monads khác:

f :: MonadReader Int m => m Int 
f = do 
    a <- ask 
    return $ 2 * a + 3 * a 

normally :: Int 
normally = f 1 
-- normally == 5 

readerly :: Reader Int Int 
readerly = do 
    result <- f 
    return $ 2 * result 

> runReader f 1 
5 
> runReader readerly 1 
10