Có phương pháp nào giống như popitem python cho mảng kết hợp trong dlang không?

Question

Tôi muốn nhận bất kỳ cặp khóa/giá trị nào từ mảng kết hợp và xóa nó. Trong python đó là:

key, value = assoc.popitem() 

Trong D Tôi làm:

auto key = assoc.byKey.front; 
auto value = assoc[key]; 
assoc.remove(key); 

Có cách nào tốt hơn để làm điều này? Có thể sử dụng byKeyValue() bên ngoài foreach không?

DMD 2.067.1

Answer 1

Có thể sử dụng byKeyValue() bên ngoài foreach?

chắc:

import std.stdio; 

void main() 
{ 
    int[string] assoc = ["apples" : 2, "bananas" : 4]; 

    while (!assoc.byKeyValue.empty) 
    { 
     auto pair = assoc.byKeyValue.front; 
     assoc.remove(pair.key); 
     writeln(pair.key, ": ", pair.value); 
    } 
} 

Có cách nào tốt hơn để làm điều này?

Tôi không nghĩ D có hàm thư viện tương đương với popitem.

Answer 2

Trước khi thậm chí suy nghĩ về nó, tôi muốn chỉ ra rằng bạn có thể viết một hàm đơn giản:

import std.typecons; 

Tuple!(K, V) popitem(K, V)(ref V[K] arr) { 
    foreach(k, v; arr) { 
     arr.remove(k); 
     return tuple(k, v); 
    } 
    throw new Exception("empty!"); 
} 
void main() { 
    int[string] cool; 
    cool["ten"] = 10; 
    cool["twenty"] = 20; 
    import std.stdio; 
    writeln(cool.popitem()); 
    writeln(cool.popitem()); 
} 

Hoặc sử dụng byKeyValue:

auto popitem(K, V)(ref V[K] arr) { 
    foreach(item; arr.byKeyValue()) { 
     arr.remove(item.key); 
     return item; 
    } 
    throw new Exception("empty!"); 
} 
void main() { 
    int[string] cool; 
    cool["ten"] = 10; 
    cool["twenty"] = 20; 
    import std.stdio; 
    auto item = cool.popitem(); 
    writeln(item.key, item.value); 
    item = cool.popitem(); 
    writeln(item.key, item.value); 
} 

Nói chung, tôi muốn khuyến khích mọi người không để sợ viết các chức năng của chính họ. Nếu bạn có thể diễn tả điều gì đó với một vài thứ hiện có, chỉ cần viết chức năng của riêng bạn, đặt tên cho nó, và sử dụng nó! Với cú pháp gọi hàm đồng nhất, bạn có thể dễ dàng viết các phương thức mở rộng cho các kiểu dựng sẵn, như tôi đã làm ở đây, và sử dụng nó như thể nó luôn ở đó.