Có chức năng Mathematica tích hợp để tìm toán tử thay vì số trong phương trình không?

Question

Làm cách nào để đạt được kết quả tốt nhất trong Mathematica?

In[1] := Solve[f[2,3]==5,f ∈ {Plus,Minus,Divide}] 

Out[1] := Plus 

Answer 1

những mong muốn cú pháp biểu thức có thể được chuyển đổi thành một bộ Solve biểu:

fSolve[expr_, f_ ∈ functions_List] := 
    Map[Solve[(expr /. f -> #) && f == #, f] &, functions] // Flatten 

Sử dụng mẫu:

In[6]:= fSolve[f[2,3] == 5, f ∈ {Plus, Subtract, Divide}] 
Out[6]= {f -> Plus} 

In[7]:= fSolve[f[4,2] == 2, f ∈ {Plus, Subtract, Divide}] 
Out[7]= {f -> Subtract, f -> Divide} 

Lợi thế của phương pháp này là toàn bộ sức mạnh của Solve vẫn khả dụng cho các biểu thức phức tạp hơn, ví dụ:

In[8]:= fSolve[D[f[x], x] < f[x], f ∈ {Log, Exp}] 
Out[8]= {f -> ConditionalExpression[Log, x Log[x]∈Reals && x>E^ProductLog[1]]} 

In[9]:= fSolve[D[f[x], x] <= f[x], f ∈ {Log, Exp}] 
Out[9]= {f -> ConditionalExpression[Log, x Log[x]∈Reals && x>=E^ProductLog[1]], 
     f -> ConditionalExpression[Exp, E^x ∈ Reals]} 

Answer 2

Tôi không biết về chức năng tích hợp sẵn, nhưng không khó để viết một bản thân. Dưới đây là một phương pháp mà bạn có thể sử dụng:

Clear@correctOperatorQ; 
correctOperatorQ[expr_, value_, 
    operators_] := (expr == value) /. Head[expr] -> # & /@ operators 

Bằng cách này, các nhà điều hành chính xác cho 2-3 là Subtract, không Minus. Kết quả ví dụ của bạn:

correctOperatorQ[f[2, 3], 5, {Plus,Subtract,Divide}] 
Out[1]={True, False, False} 

Answer 3

Hãy cho tôi biết nếu điều này làm những gì bạn muốn:

findFunction[expr_, head_ ∈ {ops__}] := 
    Quiet@Pick[{ops}, expr /. head -> # & /@ {ops}] 

findFunction[f[2, 3] == 5, f ∈ {Plus, Minus, Divide}] 

(* Out[]= {Plus} *)