perl cách chuyển đổi chuỗi thành Ngày giờ?

Question

Tôi đã cố gắng chuyển đổi một chuỗi cho đến nay trong perl, nhưng gặp lỗi.

use strict; 
use warnings; 
use DateTime; 
use Date::Manip; 

my $date = ParseDate("20111121"); 
print "today is ".$date->day_of_week."\n"; 

lỗi

Can't call method "day_of_week" without a package or object reference 

Hình như việc nhập khẩu bao bì có vấn đề ...

Cảm ơn

Answer 1

Ngày giờ không phân tích ngày tháng. Tôi muốn đi cho các mô-đun Time::Piece lõi cung cấp cho bạn strptime():

#!/usr/bin/env perl 
use strict; 
use warnings; 
use Time::Piece; 
my $t = Time::Piece->strptime("20111121", "%Y%m%d"); 
print $t->strftime("%w\n"); 

Answer 2

Từ các tài liệu mô-đun: This module does not parse dates

Bạn cần phải thêm mã ví dụ như được đề xuất trong I printed a date with strftime, how do I parse it again? để chuyển đổi từ chuỗi thành đối tượng ngày tháng.

Answer 3

DateTime chính nó không có cơ sở phân tích, nhưng có rất nhiều parsers rằng gererate đối tượng DateTime. Hầu hết thời gian, có thể bạn sẽ muốn DateTime::Format::Strptime.

use DateTime::Format::Strptime qw(); 
my $format = DateTime::Format::Strptime->new(
    pattern => '%Y%m%d', 
    time_zone => 'local', 
    on_error => 'croak', 
); 
my $dt = $format->parse_datetime('20111121'); 

Hoặc bạn có thể tự làm.

use DateTime qw(); 
my ($y,$m,$d) = '20111121' =~ /^([0-9]{4})([0-9]{2})([0-9]{2})\z/ 
    or die; 
my $dt = DateTime->new(
    year  => $y, 
    month  => $m, 
    day  => $d, 
    time_zone => 'local', 
);