Làm thế nào để so sánh thời gian ngày chuỗi trong perl?

Question

Tôi có định dạng ngày tháng này bằng chuỗi "11:56:41, 11/22/2011".

Đây là những gì tôi muốn:

So sánh hai chuỗi ngày tháng như thế nào.

$date1 = "11:56:41, 11/22/2011"; 
$date2 = "11:20:41, 11/20/2011"; 
if($date2 < $date1) { 
    do something... 
} else { 
    do nothing... 
} 

Bất kỳ ý tưởng nào tôi có thể đạt được điều này trong perl?

Answer 1

Một phương pháp hiệu quả là sắp xếp lại các trường thành một thứ tương tự.

sub to_comparable { 
    my ($date) = @_; 
    my ($H,$M,$S,$d,$m,$Y) = $date =~ m{^([0-9]{2}):([0-9]{2}):([0-9]{2}), ([0-9]{2})/([0-9]{2})/([0-9]{4})\z} 
     or die; 
    return "$Y$m$d$H$M$S"; 
} 

if (to_comparable($date2) lt to_comparable($date1)) { 
    ... 
} else { 
    ... 
} 

Answer 2

Chuyển đổi datetimes (trong trường hợp của bạn đây là datetimes địa phương vì họ không có múi giờ) vào ISO8601 thì bạn có thể so sánh chuỗi thông thường.

Để thực hiện việc chuyển đổi, bạn nên giải nén sáu thành phần từ định dạng của bạn

HH:MM:SS, mm/DD/YYYY 

và Lắp ráp lại chúng vào ISO 8601:

YYYY-MM-DDTHH:MM:SS 

Sau đó, so sánh tự từ điển bình thường sẽ làm việc.

Xem http://codepad.org/berle9um

Lặp đi lặp lại ở đây:

sub my_format_to_iso8601 { 
    $_[0] =~ /(\d\d):(\d\d):(\d\d), (\d\d)\/(\d\d)\/(\d\d\d\d)/; 
    return "$6-$4-$5T$1:$2:$3"; 
} 

$date1 = "11:56:41, 11/22/2011"; 
$date2 = "11:20:41, 11/20/2011"; 
$d1 = my_format_to_iso8601($date1); 
$d2 = my_format_to_iso8601($date2); 
print "first is $d1\n"; 
print "second is $d2\n"; 
if ($d2 < $d1) { 
    print "second is earlier\n"; 
} else { 
    print "first is earlier\n"; 
} 

PHỤ LỤC Perl mã

• Ikegami là tốt hơn nhiều.
• Thư viện ngày sẽ là bạn của bạn ở đây; chỉ cần chỉ định một chuỗi định dạng và sử dụng chức năng phân tích cú pháp của thư viện để lấy đối tượng ngày của bạn, sau đó nó sẽ có thể so sánh trực tiếp. (Điều đó nói rằng, luôn luôn thú vị khi chỉ ra rằng ISO8601 là, theo thiết kế, có thể sắp xếp theo dạng chuỗi.)

Answer 3

Trong trường hợp này, tôi đã luôn luôn sử dụng Date::Calc:

use Date::Calc; 

my $date1 = "11:56:41, 11/22/2011"; 
my $date2 = "11:20:41, 11/20/2011"; 

my @date1arr=split /[^\d]/, $date1 if($date1 =~ m!\d{2}:\d{2}:\d{2}, \d{2}/\d{2}/\d{4}!; 
my @date2arr=split /[^\d]/, $date2 if($date2 =~ m!\d{2}:\d{2}:\d{2}, \d{2}/\d{2}/\d{4}!; 

my @diff = Delta_DHMS(@date1arr, @date2arr); 
my $less; 
foreach my $d (@diff) { $less = 1 if $d < 0; } 

if($less) { ... } 

Answer 4

Thêm một giải pháp mà sử dụng sự so sánh quá tải sau khi chuyển đổi thời gian để Time::Piece đối tượng. Việc tạo ra các đối tượng có thể là quá mức cần thiết cho một cái gì đó đơn giản, nhưng chúng có thể trở nên rất hữu ích nếu bạn cần phải làm những việc khác với thời gian.

use Time::Piece; 

my $dateformat = "%H:%M:%S, %m/%d/%Y"; 

my $date1 = "11:56:41, 11/22/2011"; 
my $date2 = "11:20:41, 11/20/2011"; 

$date1 = Time::Piece->strptime($date1, $dateformat); 
$date2 = Time::Piece->strptime($date2, $dateformat); 

if ($date2 < $date1) { 
    do something... 
} else { 
    do nothing... 
} 

Answer 5

gì, đã 4 giờ và không phải là một đơn DateTime (tất cả mưa đá DateTime hùng mạnh) câu trả lời trong tầm nhìn? Bạn chưa xong, perl thuê bao ... ☻

use DateTime::Format::Strptime qw(); 
my $p = DateTime::Format::Strptime->new(pattern => '%T, %D', on_error => 'croak',); 

my $date1 = $p->parse_datetime('11:56:41, 11/22/2011'); 
my $date2 = $p->parse_datetime('11:20:41, 11/20/2011'); 

if($date2 < $date1) { 
    say "$date2 comes before $date1"; 
} else { 
    say "$date2 does not come before $date1"; 
} 

Phương pháp parse_datetime trả về trường hợp của DateTime mà so sánh các nhà khai thác và stringification đang quá tải để DTRT.

Answer 6

Tôi sử dụng unixtime.:)

tôi chuyển đổi cả hai lần để unixtime và sau đó tôi chỉ có hai số nguyên để so sánh và vì vậy tôi có thể sử dụng các toán tử <, ==,> vv

ví dụ chuyển đổi thành unixtime như sau

my $timestamp = "2014-03-25 12:33:32"; # (We assume localtime) 

# 
# To split on the space character, it's best to use the regex// 
# 
my ($date, $time) = split (/ /, $timestamp); 
my ($year, $mon, $mday) = split ('-', $date); 
my ($hour, $min, $sec) = split (':', $time); 

my $unixtime = timelocal($sec, $min, $hour, $mday, $mon-1, $year);