Lấy danh sách các tệp Excel trong một thư mục bằng cách sử dụng VBA

Question

Tôi cần lấy tên của tất cả các tệp Excel trong một thư mục và sau đó thực hiện thay đổi cho mỗi tệp. Tôi đã nhận được phần "thay đổi" được sắp xếp. Có cách nào để lấy danh sách các tệp .xlsx trong một thư mục không, ví dụ D:\Personal và lưu trữ nó trong một Chuỗi Chuỗi.

sau đó tôi cần phải lặp qua danh sách các tập tin và chạy macro trên mỗi file mà tôi figured tôi có thể làm bằng:

Filepath = "D:\Personal\" 
For Each i in FileArray 
    Workbooks.Open(Filepath+i) 
Next 

tôi đã có một cái nhìn tại this, tuy nhiên, tôi wasn' t có thể mở các tập tin vì nó lưu trữ các tên ở định dạng Variant.

Tóm lại, làm cách nào tôi có thể sử dụng VBA để lấy danh sách tên tệp Excel trong một thư mục cụ thể?

Answer 1

Ok tốt điều này có thể làm việc cho bạn, một chức năng mà phải mất một con đường và trả về một mảng tên tệp trong thư mục. Bạn có thể sử dụng câu lệnh if để chỉ nhận các tệp excel khi lặp qua mảng.

Function listfiles(ByVal sPath As String) 

    Dim vaArray  As Variant 
    Dim i   As Integer 
    Dim oFile  As Object 
    Dim oFSO  As Object 
    Dim oFolder  As Object 
    Dim oFiles  As Object 

    Set oFSO = CreateObject("Scripting.FileSystemObject") 
    Set oFolder = oFSO.GetFolder(sPath) 
    Set oFiles = oFolder.Files 

    ReDim vaArray(1 To oFiles.Count) 
    i = 1 
    For Each oFile In oFiles 
     vaArray(i) = oFile.Name 
     i = i + 1 
    Next 

    listfiles = vaArray 

End Function 

Sẽ tốt hơn nếu chúng tôi chỉ truy cập tệp trong đối tượng tệp theo số chỉ mục nhưng dường như bị hỏng trong VBA vì bất kỳ lý do gì (lỗi?).

Answer 2

Dim iIndex as Integer 
Dim ws As Excel.Worksheet 
Dim wb  As Workbook 
Dim strPath As String 
Dim strFile As String 

strPath = "D:\Personal\" 
strFile = Dir(strPath & "*.xlsx") 

Do While strFile <> "" 
    Set wb = Workbooks.Open(Filename:=strPath & strFile) 

    For iIndex = 1 To wb.Worksheets.count 
     Set ws = wb.Worksheets(iIndex) 

     'Do something here. 

    Next iIndex 

strFile = Dir 
Loop 

Answer 3

Bạn có thể sử dụng hàm Dir được tích hợp sẵn hoặc FileSystemObject.

• Dir Chức năng: VBA: Dir Function

• FileSystemObject: VBA: FileSystemObject - Files Collection

Đối với một danh sách đơn giản các tập tin, lệnh dir là khá dễ dàng để sử dụng. Nó cũng hỗ trợ các ký tự đại diện, rất hữu ích nếu bạn không muốn mọi tệp. Bí quyết để sử dụng nó là để hiểu cách gọi nó với một tham số khác với cuộc gọi mà không có một tham số.

Public Sub ListFilesDir(ByVal sPath As String, Optional ByVal sFilter As String) 

    Dim sFile As String 

    If Right(sPath, 1) <> "\" Then 
     sPath = sPath & "\" 
    End If 

    If sFilter = "" Then 
     sFilter = "*.*" 
    End If 

    'call with path "initializes" the dir function and returns the first file 
    sFile = Dir(sPath & sFilter) 

    'call it again until there are no more files 
    Do Until sFile = "" 

     Debug.Print sFile 
     'subsequent calls without param return next file 
     sFile = Dir 

    Loop 

End Sub 

Nếu bạn muốn intellisense và nhiều khả năng vượt ra ngoài nhận tên tệp, tôi sẽ đề xuất FileSystemObject. Bạn có thể thêm một tham chiếu đến để "Windows Script Host Object Model" (hoặc "Windows Scripting Runtime") và tuyên bố đối tượng của bạn như sau:

Public Sub ListFilesFSO(ByVal sPath As String) 

    Dim oFSO As FileSystemObject 
    Dim oFolder As Folder 
    Dim oFile As File 

    Set oFSO = New FileSystemObject 
    Set oFolder = oFSO.GetFolder(sPath) 
    For Each oFile In oFolder.Files 
     Debug.Print oFile.Name 
    Next 'oFile 

    Set oFile = Nothing 
    Set oFolder = Nothing 
    Set oFSO = Nothing 

End Sub