Làm cách nào để lấy danh sách tất cả các tệp có phần mở rộng ESY trong một thư mục?

Question

Trong VBA, làm cách nào để có danh sách tất cả các tệp có phần mở rộng cụ thể trong một thư mục cụ thể?

tôi vẫn chưa thể làm Application.FileSearch, bởi vì tôi đang sử dụng Excel 2007

Answer 1

Để trả lời nhận xét của bạn "vậy tôi đã biết bao nhiêu lần để chạy nó?", ví dụ này chạy cho đến khi danh sách tất cả các tệp có tên khớp với strPattern. Thay đổi hằng số strFolder.

Public Sub ListESY() 
Const strFolder As String = "C:\SomeFolder\" 
Const strPattern As String = "*.ESY" 
Dim strFile As String 
strFile = Dir(strFolder & strPattern, vbNormal) 
Do While Len(strFile) > 0 
    Debug.Print strFile '<- view this in Immediate window; Ctrl+g will take you there 
    strFile = Dir 
Loop 
End Sub 

Answer 2

Dir ("C:. \ YourPath \ * ESY", vbNormal) Trả về tập đầu tiên với phần mở rộng ESY. Mỗi lần gọi tiếp theo đến Dir() sẽ trả về lần tiếp theo.

Answer 3

Tùy chọn thay thế: sử dụng thư viện "Microsoft Scripting Runtime" (kiểm tra trong Công cụ ... Tham khảo) cho họ đối tượng FileSystemObject. Một cái gì đó như sau, có lẽ:

Public Function ESYFileCount(dir_path as String) as Long 

Dim fil As File 

    With New FileSystemObject 
     With .GetFolder(dir_path) 
      For Each fil In .Files 
       If LCase(Right(fil.Name, 4)) = ".esy" Then 
        ESYFileCount = ESYFileCount + 1 
       End If 
      Next 
     End With   
    End With 

End Function 

Answer 4

Mã sau chạy nhanh hơn khoảng 19 lần so với sử dụng FileSystemObject. Trên máy tính của tôi, việc tìm kiếm 4000 tệp trong ba drectories khác nhau mất 1,57 giây bằng FileSystemObject, nhưng chỉ 0,08 giây sử dụng mã này.

Public Function CountFilesWithGivenExtension(_ 
      i_strFolderWithTerminalBackslant As String, _ 
      i_strExtensionIncludingPeriod As String _ 
     ) As Long 

     If Len(Dir$(i_strFolderWithTerminalBackslant & "*" _ 
      & i_strExtensionIncludingPeriod)) > 0 Then 

      CountFilesWithGivenExtension = 1 

      While Len(Dir$) > 0 

      CountFilesWithGivenExtension = _ 
        CountFilesWithGivenExtension + 1 

      DoEvents 

      Wend 
     Else 
      CountFilesWithGivenExtension = 0 
     End If 

    End Function 

mẫu sử dụng:

Debug.Print CountFilesWithGivenExtension("C:\", ".ex*") 

(Các "DoEvents" là không cần thiết, nhưng cho phép bạn sử dụng Pause/Break nếu cần thiết.)