Ghép các biến macro được trích dẫn

Question

Tôi chỉ đang cố nối hai biến macro được trích dẫn nhưng dường như không có cách nào dễ dàng.

Giả sử chúng ta có:

%LET VAR1="This is not the greatest song in the world"; 
%LET VAR2="this is just a tribute."; 

%LET TRIBUTE=%SYSFUNC(CATX(%STR(),&VAR1,&VAR2)); 
%PUT &TRIBUTE; 

Tôi thực sự muốn:

"This is not the greatest song in the world this is just a tribute." 

Nhưng đoạn mã trên thực sự mang lại:

"This is not the greatest song in the world" "this is just a tribute." 

Vì vậy, tôi thử đặt %QUOTE(), %BQUOTE, vv. xung quanh &VAR1 và %VAR2 với hy vọng sẽ vạch mặt dấu ngoặc kép nhưng tôi nhận được kết quả tương tự.

Điều duy nhất làm việc cho tôi là:

%LET TRIBUTE="%SUBSTR(&VAR1.,2,%LENGTH(&VAR1.)-2) %SUBSTR(&VAR2.,2,%LENGTH(&VAR2.)-2)"; 

Nhưng điều này là xấu xí và có thể nhận được dài rất nhanh. Có cách nào tốt hơn không?

Answer 1

Bạn có thể sử dụng COMPRESS để thực hiện việc này.

%LET VAR1="This is not the greatest song in the world"; 
%LET VAR2="this is just a tribute."; 


%let VAR3=%sysfunc(compress(&VAR1,%str(%"))); 
%put &=var1 &=var3; 

Hơi khó để xóa dấu ngoặc kép, nhưng nó hoạt động.

Bạn cũng có thể thực hiện việc này trong chức năng FCMP hoặc macro kiểu hàm; đây là một ví dụ.

%macro unquote_string(string=); 
%sysfunc(compress(&string.,%str(%'%"))) 
%mend unquote_string; 

%let VAR3="%unquote_string(string=&var1.) %unquote_string(string=&var2.)"; 
%put &=var3.; 

Lưu ý bạn không nên sử dụng chức năng CAT để nối các biến macro. Chúng chỉ là văn bản, vì vậy hãy gõ văn bản sau khi người kia tự động ghép chúng lại.

Tuy nhiên, câu trả lời thực sự cho câu hỏi của bạn về 'Có cách nào tốt hơn', không lưu trữ các trích dẫn trong biến macro. Hầu hết thời gian bạn nên lưu trữ các biến vĩ mô w/o báo giá và sử dụng nó trong dấu ngoặc kép khi cần thiết. SAS Macros không tôn trọng các dấu ngoặc kép như bất cứ điều gì đặc biệt - chúng chỉ là một ký tự trong một chuỗi - vì vậy chúng không có một công cụ cụ thể để xử lý việc này.

Answer 2

Tôi sẽ diễn giải câu trả lời thực sự của Joe - không lưu trữ các trích dẫn trong biến macro. Dấu nháy đơn và kép trong ngôn ngữ macro không khác với bất kỳ ký tự nào khác. Những gì bạn nên làm là trì hoãn giới thiệu các dấu ngoặc kép cho đến khi bạn thực sự cần chúng. Điều này sẽ cho kết quả sạch hơn, linh hoạt hơn, dễ đọc hơn và mã không có lỗi.

Code:

Thông báo Tôi đã gỡ bỏ các dấu ngoặc kép và nối các chuỗi Tôi chỉ liệt kê chúng một sau khi khác:

%LET VAR1=This is not the greatest song in the world; 
%LET VAR2=this is just a tribute.; 
%LET TRIBUTE=&VAR1 &VAR2; 

Ví dụ 1

Không cần trích dẫn để in ra chuỗi mong muốn khi chúng tôi đang sử dụng câu lệnh %put trong ví dụ đầu tiên này - vì lý do này tôi đã để lại dấu ngoặc kép:

%PUT &TRIBUTE; 

Output:

This is not the greatest song in the world this is just a tribute. 

Ví dụ 2

Quotes được yêu cầu bởi vì bây giờ chúng ta đang ở đất dữ liệu bước:

data _null_; 
    put "&TRIBUTE"; 
run; 

Output:

This is not the greatest song in the world this is just a tribute. 

Lưu ý rằng cả hai ví dụ này đều cho rằng bạn thực sự không muốn in dấu ngoặc kép trên màn hình.