Loại dòng Gnuplot

Question

Làm cách nào để vẽ các loại đường khác nhau trên gnuplot? Tôi phải vẽ các màu khác nhau. Kịch bản của tôi tham gia một số tệp và tôi nghĩ đó là lý do tại sao các dòng không phải là dấu gạch ngang. Chỉ có hai trong số bốn người bị tiêu tan. Cảm ơn Felipe

#!/usr/bin/gnuplot 

set grid 
set title 'Estado dos arquivos no BTRIM com peers de comportamento condicionado' 
set xlabel 'Tempo discreto' 
set ylabel 'Quantidade de arquivos' 
set style line 1 lc rgb '#0060ad' lt 1 lw 2 pi -1 ps 1.0 
set style line 2 lc rgb '#dd181f' lt 9 lw 2 pi -1 ps 1.0 
set style line 3 lc rgb '#29c524' lt 6 lw 2 pi -1 ps 1.0 
set style line 4 lc rgb '#7D72F9' lt 7 lw 2 pi -1 ps 1.0 
set style line 5 lc rgb '#000000' lt 8 lw 2 pi -1 ps 1.0 

set termoption dashed 
#set pointintervalbox 0 
#set boxwidth 0.1 
#set style fill solid 

plot '<paste ../00/StatisticNormal.txt ../01/StatisticNormal.txt ../02/StatisticNormal.txt ../03/StatisticNormal.txt ../04/StatisticNormal.txt ../05/StatisticNormal.txt ../06/StatisticNormal.txt ../07/StatisticNormal.txt ../08/StatisticNormal.txt ../09/StatisticNormal.txt' smooth unique with line ls 1 title 'Normais', \ 
'<paste ../00/StatisticVogue.txt ../01/StatisticVogue.txt ../02/StatisticVogue.txt ../03/StatisticVogue.txt ../04/StatisticVogue.txt ../05/StatisticVogue.txt ../06/StatisticVogue.txt ../07/StatisticVogue.txt ../08/StatisticVogue.txt ../09/StatisticVogue.txt' smooth unique with line ls 2 title 'na Moda', \ 
'<paste ../00/StatisticPopular.txt ../01/StatisticPopular.txt ../02/StatisticPopular.txt ../03/StatisticPopular.txt ../04/StatisticPopular.txt ../05/StatisticPopular.txt ../06/StatisticPopular.txt ../07/StatisticPopular.txt ../08/StatisticPopular.txt ../09/StatisticPopular.txt' smooth unique with line ls 3 title 'Populares', \ 
'<paste ../00/StatisticRarity.txt ../01/StatisticRarity.txt ../02/StatisticRarity.txt ../03/StatisticRarity.txt ../04/StatisticRarity.txt ../05/StatisticRarity.txt ../06/StatisticRarity.txt ../07/StatisticRarity.txt ../08/StatisticRarity.txt ../09/StatisticRarity.txt' smooth unique with line ls 4 title 'Raros' 

pause -1 

Answer 1

Cho đến phiên bản 4.6

Loại gạch ngang của một linestyle được cho bởi linetype, mà cũng không chọn màu đường trừ khi bạn explicitely thiết lập một một khác với linecolor.

Tuy nhiên, sự hỗ trợ cho các đường đứt nét phụ thuộc vào thiết bị đầu cuối được chọn:

1. Một số thiết bị đầu cuối không hỗ trợ các đường đứt nét, giống như png (sử dụng libgd)
2. thiết bị đầu cuối khác, như pngcairo, hỗ trợ đứt nét nhưng theo mặc định, nó sẽ bị tắt. Để bật tính năng này, hãy sử dụng set termoption dashed hoặc set terminal pngcairo dashed ....
3. Các mẫu dấu gạch ngang chính xác khác nhau giữa các thiết bị đầu cuối. Để xem các định nghĩa linetype, sử dụng test lệnh:

Chạy

set terminal pngcairo dashed 
set output 'test.png' 
test 
set output 

cho:

trong khi đó, các thiết bị đầu cuối postscript lãm khác nhau mẫu dấu gạch ngang:

set terminal postscript eps color colortext 
set output 'test.eps' 
test 
set output 

Phiên bản 5.0

Bắt đầu với phiên bản 5.0 các thay đổi sau liên quan đến linetypes, mẫu dấu gạch ngang và màu sắc dòng được giới thiệu:

• Một tham số mới dashtype đã được giới thiệu:

  Để lấy các mẫu gạch ngang được xác định trước, hãy sử dụng ví dụ

  plot x dashtype 2 
  

  Bạn cũng có thể xác định mô hình tùy chỉnh dấu gạch ngang như

  plot x dashtype (3,5,10,5),\ 
      2*x dashtype '.-_' 
  

• Các tùy chọn thiết bị đầu cuối dashed và solid được bỏ qua. Theo mặc định, tất cả các dòng đều chắc chắn. Để thay đổi chúng thành tiêu tan, hãy sử dụng ví dụ:

  set for [i=1:8] linetype i dashtype i 
  

• Bộ màu mặc định đã thay đổi.Bạn có thể chọn giữa ba bộ màu sắc khác nhau với set colorsequence default|podo|classic: