Đọc giá trị đăng ký có chứa khoảng trắng bằng cách sử dụng tệp hàng loạt

Question

Tôi có tệp lô đọc giá trị đăng ký.

Tuy nhiên, mục nhập mà tôi đang đọc có chứa khoảng trắng và tôi dường như chỉ ghi lại mọi thứ trước ký tự khoảng trắng đầu tiên khi đặt biến của tôi.

set KEY_NAME="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\My Entry" 
set VALUE_NAME=Home 

FOR /F "usebackq skip=2 tokens=1-3" %%A IN (`REG QUERY %KEY_NAME% /v %VALUE_NAME% 2^>nul`) DO (
    set ValueName=%%A 
    set ValueType=%%B 
    set Home=%%C 
) 

if defined ValueName (
    @echo Home = %Home% 
) else (
    @echo %KEY_NAME%\%VALUE_NAME% not found. 
) 

Các mục đăng ký nhà thực sự chứa chuỗi này: "C: \ Program Files (x86) \ dir1 \ dir2" và tập tin thực thi chỉ chụp này: C: \ Program

Không ai có một ý tưởng làm thế nào để sửa lỗi này?

Cảm ơn

Answer 1

Vấn đề này xảy ra bởi vì các chuỗi chứa dấu cách và phần thứ hai của chuỗi (có thể nhiều phần nếu có không gian hơn) được coi là dấu hiệu khác (trong 4, 5, vv) Để khắc phục này, vượt qua phần còn lại của dòng đến %% C với dấu hoa thị như thế này:

FOR /F "usebackq skip=2 tokens=1,2*" %%A IN (`REG QUERY %KEY_NAME% /v %VALUE_NAME% 2^>nul`) DO (
    set ValueName=%%A 
    set ValueType=%%B 
    set Home=%%C 
) 

dấu (*) có nghĩa là để vượt qua phần còn lại của dòng vào biến tiếp theo (với tất cả các dấu cách).

Answer 2

@ECHO OFF 
SETLOCAL 
set KEY_NAME="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\My Entry" 
set KEY_NAME="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Space Sciences Laboratory, U.C. Berkeley\BOINC Setup" 
set VALUE_NAME=migrationdir 

FOR /F "usebackq skip=2 tokens=1,2*" %%A IN (
`REG QUERY %KEY_NAME% /v %VALUE_NAME% 2^>nul`) DO (
    set "ValueName=%%A" 
    set "ValueType=%%B" 
    set Home="%%C" 
) 

IF DEFINED home SET home=%home:"=% 
if defined Home echo Home = %Home% 
if NOT defined Home echo %KEY_NAME%\%VALUE_NAME% not found. 

Vì tôi không có ...\My Entry làm khóa, tôi đã thay thế khóa mà mình có.

Mục đầu tiên - vì dữ liệu được yêu cầu chứa không gian và không gian là dấu phân cách mặc định, bạn cần sử dụng 1,2* làm mã thông báo - thứ nhất, thứ hai và phần còn lại.

Khó khăn nhỏ bên cạnh là các mục dữ liệu CŨNG chứa ) whic được hiểu như là sự đóng ngoặc của FOR/f do đó đưa ra một lỗi - trong trường hợp của bạn, \Dir1\Dir2 không mong đợi đây

Một cách để khắc phục điều này là để báo giá, sau đó chia giá trị được gán cho home

Nhưng một lần nữa, dấu ngoặc đơn trong home sẽ kết thúc phần TRUE của câu lệnh IF.

chuyển đổi sự hiện diện/vắng mặt của giá trị được gán cho HOME vượt qua điều này. Rõ ràng, điều tương tự có thể được nói cho Valuename mặc dù có một thất bại ẩn không thành công ở đây.

Nếu không tìm thấy mục đăng ký được yêu cầu, thì SET s trong FOR/f không được thực hiện, do đó giá trị của ba biến không thay đổi từ bất kỳ giá trị nào có thể có trước khi thực hiện FOR/f. Do đó, nếu home (hoặc valuename nếu bạn chọn sử dụng giá trị đó) có giá trị là someexistingvalue trước for/f thì kết quả không mong muốn có thể được trình bày.

(BTW - đó là hợp pháp và gọn gàng-tìm cách để phá vỡ for/f tại một trong hai hoặc cả hai dấu ngoặc đơn của mệnh đề IN)