Mở rộng bí danh zsh

Question

Có thể định cấu hình zsh để mở rộng bí danh chung trong khi hoàn thành tab không? Ví dụ, tôi có bí danh chung:

alias -g '...'='../..' 
alias -g '....'='../../..' 

nhưng khi tôi gõ, ví dụ, cd .../some<tab> nó sẽ không mở rộng đến cd .../something hay cd ../../something. Do đó, tôi thường xuyên không sử dụng các bí danh tiện dụng này vì chúng không tương thích với hoàn thành tab.

Answer 1

Tôi là một người sử dụng của Mikael Magnusson của rationalise-dot. Từ zshrc của tôi:

# This was written entirely by Mikael Magnusson (Mikachu) 
# Basically type '...' to get '../..' with successive .'s adding /.. 
function rationalise-dot { 
    local MATCH # keep the regex match from leaking to the environment 
    if [[ $LBUFFER =~ '(^|/| |  |'$'\n''|\||;|&)\.\.$' ]]; then 
     LBUFFER+=/ 
     zle self-insert 
     zle self-insert 
    else 
     zle self-insert 
    fi 
} 
zle -N rationalise-dot 
bindkey . rationalise-dot 
# without this, typing a . aborts incremental history search 
bindkey -M isearch . self-insert 

Answer 2

Hãy thử tra cứu chữ viết tắt zsh. Chúng cho phép bạn nhập "chữ viết tắt" tự động được thay thế bằng biểu mẫu đầy đủ của nó khi bạn nhấn phím ảo chẳng hạn như dấu cách. Vì vậy, bạn có thể tạo một cái thay đổi ...<SPACE> thành ../...

Ví dụ, đây là những gì bạn cần trong hồ sơ của bạn:

typeset -A abbrevs 
abbrevs=(
     "..." "../.." 
     "...." "../../.."   
) 

#create aliases for the abbrevs too 
for abbr in ${(k)abbrevs}; do 
    alias -g $abbr="${abbrevs[$abbr]}" 
done 

my-expand-abbrev() { 
    local MATCH 
    LBUFFER=${LBUFFER%%(#m)[_a-zA-Z0-9]#} 
    LBUFFER+=${abbrevs[$MATCH]:-$MATCH} 
    zle self-insert 
} 

bindkey " " my-expand-abbrev