Làm cách nào để xuất số nguyên bằng cách sử dụng phương thức Put_Line?

Question

Tôi không thể lấy chương trình này để biên dịch vì nó dường như không in các biến số nguyên cùng với các chuỗi trong phương thức Put_Line. Tôi đã xem xét mã nguồn trực tuyến và nó hoạt động khi họ làm điều đó vì vậy tôi đang đi sai. Cảm ơn bạn đã giúp đỡ.

with Ada.Text_IO;      use Ada.Text_IO; 
with Ada.Integer_Text_IO;   use Ada.Integer_Text_IO; 

procedure MultiplicationTable is 

    procedure Print_Multiplication_Table(Number :in Integer; Multiple :in Integer) is 
     Result : Integer; 
    begin 
     for Count in 1 ..Multiple 
     loop 
      Result := Number * Count; 
      Put_Line(Number & " x " & Count & " = " & Result); 
     end loop; 
    end Print_Multiplication_Table; 
    Number : Integer; 
    Multiple : Integer; 

begin 
    Put("Display the multiplication of number: "); 
    Get(Number); 
    Put("Display Multiplication until number: "); 
    Get(Multiple); 
    Print_Multiplication_Table(Number,Multiple); 
end MultiplicationTable;` 

Answer 1

Vấn đề là bạn đang sử dụng & với chuỗi và số nguyên. Hãy thử một trong các cách sau:

Thay Number bên trong tham số của đặt với Integer'Image(Number)

Hoặc phá vỡ các Put_Line vào các thành phần mà bạn muốn; ví dụ:

-- Correction to Put_Line(Number & " x " & Count & " = " & Result); 
Put(Number); 
Put(" x "); 
Put(Count); 
Put(" = "); 
Put(Result); 
New_Line(1); 

Answer 2

Hãy thử điều này:

Put_Line(Integer'Image(Number) & " x " & Integer'Image(Count) & " = " & Integer'Image(Result)); 

Answer 3

Bạn đã có with và use khoản cho Ada.Integer_Text_IO, nhưng bạn không thực sự sử dụng nó.

Thay đổi này:

Put_Line(Number & " x " & Count & " = " & Result); 

này:

Put(Number); Put(" x "); Put(Count); Put(" = "); Put(Result); New_Line; 

(Tôi thường sẽ không đặt nhiều câu lệnh trên cùng một dòng, nhưng trong trường hợp này nó có ý nghĩa.)

Lưu ý rằng Integer'Image thêm vào các số nguyên không âm với khoảng trắng, thứ mà tôi luôn thấy rất khó chịu; Ada.Integer_Text_IO.Put không làm điều đó (trừ khi bạn yêu cầu).

Bạn thể xác định quá tải "&" chức năng, một cái gì đó như thế này:

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & Integer'Image(Right); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return Integer'Image(Left) & Right; 
end "&"; 

mà sẽ làm cho gốc Put_Line cuộc gọi của bạn hợp lệ, nhưng nhiều Put gọi là phong cách có lẽ tốt hơn.

Answer 4

Dựa trên câu trả lời (và một bình luận trong một câu hỏi khác) từ Keith Thompson, đây là một chương trình Ada đầy đủ mà có thể cho ra các chuỗi và số nguyên với &, sử dụng Put_Line, nhưng không có chỗ mà Integer'Image sẽ khác thêm vào trước:

with Ada.Text_IO; use Ada.Text_IO; 
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO; 

procedure Main is 

function lstrip(S: String) return String is 
begin 
    if S(S'First) = ' ' then 
     return S(S'First+1 .. S'Last); 
    else 
     return S; 
    end if; 
end; 

function "&"(Left: String; Right: Integer) return String is 
begin 
    return Left & lstrip(Integer'Image(Right)); 
end "&"; 

function "&"(Left: Integer; Right: String) return String is 
begin 
    return lstrip(Integer'Image(Left)) & Right; 
end "&"; 

begin 
    Put_Line("x=" & 42); 
end Main;