Các lớp lồng nhau riêng

Question

Tôi muốn tạo một lớp lồng nhau chỉ có thể hiển thị và được hiển thị từ lớp cha.
Nhưng tôi cũng muốn có thể sử dụng một thể hiện của lớp lồng nhau thông qua một biến công khai của lớp cha.
Tôi đã cố gắng đặt lớp lồng nhau là riêng tư hoặc đặt hàm tạo của lớp lồng nhau là riêng tư, nhưng nó sẽ không biên dịch.
Có thể thực hiện việc này trong .NET không?

này biên dịch và các công trình, nhưng các lớp lồng nhau có thể được sử dụng bởi bất cứ ai:

Public Class OuterClass 
     Public X As Integer = 123 
     Public NestedClassInstance As New NestedClass(Me) 

     Public Class NestedClass 
      Private Parent As OuterClass 

      Public Sub New(ByVal _Parent As OuterClass) 
       Parent = _Parent 
      End Sub 

      Public Sub GetParentX() 
       Debug.WriteLine("X = " & Parent.X.ToString) 
      End Sub 
     End Class 
    End Class 

    Sub Main() 
     Dim OuterClassInstance As New OuterClass 
     OuterClassInstance.NestedClassInstance.GetParentX() 
    End Sub 

Answer 1

Thông thường lớp lồng nhau Riêng tư thực hiện giao diện hoặc kế thừa một lớp khác và lớp giao diện/cơ sở được hiển thị. Điều này rất hữu ích khi bạn muốn ẩn việc triển khai cho lớp cha. Một cái gì đó như thế này:

Module EntryPoint 
    Sub Main() 
     Dim OuterClassInstance As New OuterClass 
     OuterClassInstance.NestedClassInstance.GetParentX() 
    End Sub 
End Module 

Public Class OuterClass 
    Public X As Integer = 123 
    Public NestedClassInstance As ISomeImplementation = New NestedClass(Me) 

    Private Class NestedClass 
     Implements ISomeImplementation 
     Private Parent As OuterClass 

     Public Sub New(ByVal _Parent As OuterClass) 
      Parent = _Parent 
     End Sub 

     Public Sub GetParentX() Implements ISomeImplementation.GetParentX 
      Debug.WriteLine("X = " & Parent.X.ToString) 
     End Sub 
    End Class 
End Class 

Public Interface ISomeImplementation 
    Sub GetParentX() 
End Interface 

Answer 2

Bạn không thể có một lớp lồng nhau tin rằng cũng được tiếp xúc thông qua một giao diện công cộng.

Đây là một trong hai hoặc đề xuất - hoặc lớp lồng nhau là riêng tư hoặc không phải là lớp lồng nhau.

Tùy chọn là khai báo giao diện với hợp đồng bạn muốn lớp lồng nhau triển khai (với một số công cụ tái cấu trúc bạn có thể trích xuất giao diện từ lớp) và hiển thị giao diện, trong khi vẫn giữ riêng lớp lồng nhau.

Answer 3

Nếu bạn chỉ cố gắng giữ khách hàng sử dụng đối tượng bên ngoài thư viện của bạn thì chỉ cần tạo hàm tạo friend. Bằng cách đó chỉ có mã trong hội của bạn mới có thể tạo đối tượng.