Unity Shader làm nổi bật chồng lên nhau

Question

Tôi đang cố viết một bóng đổ cho sự thống nhất sẽ làm nổi bật các phần chồng chéo của các mắt lưới. Nó sẽ làm việc cho một đối tượng chồng chéo chính nó cũng như nhiều đối tượng.

Kết quả sẽ giống như hình ảnh đính kèm.

Đầu tiên tôi đã cố gắng thực hiện điều này với phát hiện va chạm nhưng tôi nghĩ rằng cách tốt nhất là viết bóng đổ.

Tôi không quen thuộc với các trình đổ bóng nên nếu có ai có thể giúp tôi, tôi sẽ biết ơn.

Tôi nghĩ rằng nó có thể được thực hiện bằng cách sử dụng shaders stencil như ở đây http://docs.unity3d.com/Manual/SL-Stencil.html nhưng shader này chỉ hiển thị giao điểm của hai đối tượng mà không cần render toàn bộ đối tượng.

Tôi cũng thấy đổ bóng dựa trên Depth (https://chrismflynn.wordpress.com/2012/09/06/fun-with-shaders-and-the-depth-buffer/) nhưng điều này cũng làm việc trên hai đối tượng và không hoạt động trên một lưới trùng tự

Về @Zze bình luận với ý tưởng về hai đèo tôi có bây giờ hai shaders . Và nó hoạt động trên hai đối tượng khi có một đối tượng và một đối tượng khác có thứ hai.

Có lẽ ai cũng có thể giúp tôi cách kết hợp nó thành một trình đổ bóng cũng sẽ hoạt động trong đối tượng sẽ chồng lên nhau?

ShaderOne

Shader "Custom/ShaderOne" 
{ 
    SubShader { 
     Tags { "RenderType"="Opaque" "Queue"="Geometry"} 
     Pass { 
      Stencil { 
       Ref 2 
       Comp always 
       Pass keep 
       Fail decrWrap 
       ZFail keep 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 
      struct appdata { 
       float4 vertex : POSITION; 
      }; 
      struct v2f { 
       float4 pos : SV_POSITION; 
      }; 
      v2f vert(appdata v) { 
       v2f o; 
       o.pos = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 
      half4 frag(v2f i) : SV_Target { 
       return half4(0,1,0,1); 
      } 
      ENDCG 
     } 
     Pass { 
      Stencil { 
       Ref 2 
       Comp equal 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 
      struct appdata { 
       float4 vertex : POSITION; 
      }; 
      struct v2f { 
       float4 pos : SV_POSITION; 
      }; 
      v2f vert(appdata v) { 
       v2f o; 
       o.pos = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 
      half4 frag(v2f i) : SV_Target { 
       return half4(0,0,1,1); 
      } 
      ENDCG 
     } 

    } 
} 

ShaderTwo

Shader "Custom/ShaderTwo" 
{ 
    SubShader { 
     Tags { "RenderType"="Opaque" "Queue"="Geometry"} 
     Pass { 
      Stencil { 
       Ref 2 
       Comp always 
       Pass replace 
       ZFail keep 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 
      struct appdata { 
       float4 vertex : POSITION; 
      }; 
      struct v2f { 
       float4 pos : SV_POSITION; 
      }; 
      v2f vert(appdata v) { 
       v2f o; 
       o.pos = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 
      half4 frag(v2f i) : SV_Target { 
       return half4(1,0,0,1); 
      } 
      ENDCG 
     } 
    } 
} 

Kết quả trông giống như một hình ảnh gắn liền

Answer 1

Vấn đề này có thể được giải quyết với sự giúp đỡ của Stencil đệm và một, hai-pass đổ bóng. Ý tưởng là như sau:

• Vượt qua đầu tiên so sánh giá trị trong bộ đệm stencil với 0. Trong cả hai trường hợp (vượt qua/thất bại) tăng giá trị trong bộ đệm.
• Lần vượt qua thứ hai so sánh giá trị trong bộ đệm stencil với 1. Nếu giá trị tham chiếu 1 nhỏ hơn, chúng tôi vượt qua và làm nổi bật pixel trùng lặp.

Bạn có thể muốn thêm đèo rằng cũng giống như thứ hai, nhưng với giá trị tham khảo khác nhau để làm nổi bật các khu vực chồng lấn hai lần, ba lần, vv

Trong ký hiệu shaderlab Unity, nó nên có một cái gì đó như thế:

Pass 
    { 
     Stencil { 
      Ref 0 
      Comp Equal 
      Pass IncrSat 
      Fail IncrSat 
     } 

     // Shader for not overlapping regions goes here. 
    } 

    Pass 
    { 
     Stencil { 
      Ref 1 
      Comp Less 
     } 

     // Shader for one-time overlapping regions goes here. 
    } 

    Pass 
    { 
     Stencil { 
      Ref 2 
      Comp Less 
     } 

     // Shader for two-time overlapping regions goes here. 
    } 

Ví dụ:

Shader:

Shader "Unlit/Stencil" 
{ 
    Properties 
    { 
     _MainTex ("Texture", 2D) = "white" {} 
    } 
    SubShader 
    { 
     Tags { "RenderType"="Opaque" } 
     LOD 100 

     Pass 
     { 
      Stencil { 
       Ref 0 
       Comp Equal 
       Pass IncrSat 
       Fail IncrSat 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 

      #include "UnityCG.cginc" 

      struct appdata 
      { 
       float4 vertex : POSITION; 
      }; 

      struct v2f 
      { 
       float4 vertex : SV_POSITION; 
      }; 

      v2f vert (appdata v) 
      { 
       v2f o; 
       o.vertex = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 

      fixed4 frag (v2f i) : SV_Target 
      { 
       fixed4 col = fixed4(0.0, 0.0, 1.0, 1.0); 
       return col; 
      } 
      ENDCG 
     } 

     Pass 
     { 
      Stencil { 
       Ref 1 
       Comp Less 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 

      #include "UnityCG.cginc" 

      struct appdata 
      { 
       float4 vertex : POSITION; 
      }; 

      struct v2f 
      { 
       float4 vertex : SV_POSITION; 
      }; 

      v2f vert (appdata v) 
      { 
       v2f o; 
       o.vertex = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 

      fixed4 frag (v2f i) : SV_Target 
      { 
       fixed4 col = fixed4(1.0, 1.0, 0.0, 1.0); 
       return col; 
      } 
      ENDCG 
     } 

     Pass 
     { 
      Stencil { 
       Ref 2 
       Comp Less 
      } 

      CGPROGRAM 
      #pragma vertex vert 
      #pragma fragment frag 

      #include "UnityCG.cginc" 

      struct appdata 
      { 
       float4 vertex : POSITION; 
      }; 

      struct v2f 
      { 
       float4 vertex : SV_POSITION; 
      }; 

      v2f vert (appdata v) 
      { 
       v2f o; 
       o.vertex = mul(UNITY_MATRIX_MVP, v.vertex); 
       return o; 
      } 

      fixed4 frag (v2f i) : SV_Target 
      { 
       fixed4 col = fixed4(1.0, 0.0, 0.0, 1.0); 
       return col; 
      } 
      ENDCG 
     } 
    } 
}