Cách xác minh xem một đối tượng có thuộc tính nhất định không?

Question

Tôi muốn sử dụng giá trị của thuộc tính dự kiến ​​hoặc mặc định được chỉ định. Làm thế nào để đạt được điều này trong groovy?

Hãy nhìn vào ví dụ:

def printName(object) { 
    //if object has initialized property 'name' - print 'name', otherwise print ToString 
    if (object<some code here>name && object.name) { 
     print object.name 
    } else { 
     print object 
    } 
} 

Answer 1

Bạn có thể sử dụng hasProperty. Ví dụ:

if (object.hasProperty('name') && object.name) { 
    println object.name 
} else { 
    println object 
} 

Nếu bạn đang sử dụng một biến cho tên thuộc tính, bạn có thể sử dụng này:

String propName = 'name' 
if (object.hasProperty(propName) && object."$propName") { 
    ... 
} 

Answer 2

Giả sử bạn object là một lớp Groovy, bạn có thể sử dụng hasProperty trong đối tượng metaClass như vậy:

def printName(o) { 
    if(o.metaClass.hasProperty(o, 'name') && o.name) { 
    println "Printing Name : $o.name" 
    } 
    else { 
    println o 
    } 
} 

Vì vậy, sau đó đưa hai lớp:

class Named { 
    String name 
    int age 

    String toString() { "toString Named:$name/$age" } 
} 

class Unnamed { 
    int age 

    String toString() { "toString Unnamed:$age" } 
} 

Bạn có thể tạo cá thể o f họ, và thử nghiệm:

def a = new Named(name: 'tim', age: 21) 
def b = new Unnamed(age: 32) 

printName(a) 
printName(b) 

nào nên đầu ra:

Printing Name : tim 
toString Unnamed:32 

Answer 3

Nếu tôi chỉ đơn giản là muốn khẳng định rằng một đối tượng có một số tài sản, tôi chỉ kiểm tra sau:

assertNotNull(myObject.hasProperty('myProperty').name) 

Nếu myObject không có myProperty sự khẳng định sẽ thất bại với một con trỏ ngoại lệ null:

java.lang.NullPointerException: Cannot get property 'name' on null object 

Answer 4

Bạn có thể viết phương pháp riêng của bạn thông qua meta-lập trình:

class Foo { 
    def name = "Mozart" 
} 

def f = new Foo() 

Object.metaClass.getPropertyOrElse = { prop, defaultVal -> 
    delegate.hasProperty(prop) ? delegate."${prop}" : defaultVal 
} 

assert "Mozart" == f.getPropertyOrElse("name", "") 
assert "Salzburg" == f.getPropertyOrElse("city", "Salzburg")