Ngày tương đối trong ColdFusion

Question

Tìm kiếm một hàm như this trong ColdFusion, cho phép tôi hiển thị ngày tháng là "10 phút trước" hoặc "2 ngày trước" hoặc "một tháng trước".

Answer 1

Mặc dù về cơ bản không khác so với udf, tôi thích this guy's approach. Không cao được thử nghiệm, nhưng bạn cũng có thể làm một cái gì đó như thế này:

Sửa Bạn đã không đề cập đến một phiên bản, vì vậy tôi cho rằng CF8

<cffunction name="relativeDate" returnType="string" access="public" output="false"> 
    <cfargument name="theDate" type="date"> 
    <cfset var x  = "" /> 
    <cfset var diff = "" />  
    <cfset var result = "unknown" />  
    <cfset var dateNow = now() /> 
    <cfset var codes = [ "yyyy", "m", "ww", "d", "h", "n", "s" ] /> 
    <cfset var names = [ "year", "month", "week", "day", "hour", "minute", "second" ] /> 

    <cfif dateCompare(arguments.theDate, now()) gt 0> 
     <!--- replace with other code to handle future dates ....---> 
     <cfthrow message="Future date handling not implemented"> 
    </cfif> 

    <!--- check each date period ...---> 
    <cfloop from="1" to="#arrayLen(codes)#" index="x"> 
     <cfset diff = abs(dateDiff(codes[x], arguments.theDate, dateNow)) /> 
     <!--- this is the greatest date period ---> 
     <cfif diff gt 0 > 
      <cfif diff gt 1> 
       <cfset result = "about "& diff &" "& names[x] &"s ago" /> 
      <cfelseif names[x] eq "hour"> 
       <cfset result = "about an "& names[x] &" ago" /> 
      <cfelse> 
       <cfset result = "about a "& names[x] &" ago" /> 
      </cfif> 

      <cfbreak> 
     </cfif> 
    </cfloop>  

    <cfreturn result /> 
</cffunction> 

Answer 2

Bạn có thể thử udf này từ cflib.org: http://cflib.org/udf/ago