Set "Image File Execution Options" sẽ luôn luôn mở file exe có tên là mặc định

Question

Như this link suggests, tôi muốn thay thế Notepad.exe với Notepad2.exe sử dụng "Image File Execution Tùy chọn" chức năng bằng cách chạy lệnh

reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" 
     /v "Debugger" /t REG_SZ /d "\"c:\windows\Notepad2.exe\" /z" /f 

Nhưng khi tôi chạy notepad nó vẫn mở file

c: \ windows \ notepad.exe

trong notepad2.exe dưới dạng tệp văn bản theo mặc định.

Có cách nào để tránh điều đó không?

Tôi biết sử dụng công nghệ Notepad.exe này sẽ là thông số đầu tiên được chuyển đến Notepad2.exe. nhưng tôi không biết làm thế nào để tránh điều này :(

Answer 1

Từ Here Thay thế Notepad của Windows với Notepad2 4.1.24 (hoặc mới hơn)

Tính đến phiên bản 4.1.24, việc phát hành chính thức của Notepad2 hỗ trợ phương pháp này để thay thế Windows Notepad, vì vậy các bước được nêu ở trên sẽ hoạt động tốt Tuy nhiên, không có hỗ trợ để thực hiện thay thế Notepad tự động, vì bản phát hành chính thức của Notepad2 sẽ không sửa đổi sổ đăng ký hệ thống. các tệp thông qua danh sách nhảy Windows 7, theo mặc định (điều này yêu cầu đăng ký các ứng dụng trong hệ thống đăng ký, trước tiên).Cũng lưu ý rằng thay thế Notepad tự động có thể có tác dụng không mong muốn nếu Notepad2 được sử dụng như một thay thế Notepad từ thiết bị di động và trạng thái ban đầu không được khôi phục khi ngắt kết nối thiết bị.

Một kịch bản hàng loạt để chạy từ thư mục Notepad2 và thay thế Notepad của Windows có thể trông như thế này (yêu cầu đặc quyền nâng cao):

reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /v "Debugger" /t REG_SZ /d "\"%~dp0Notepad2.exe\" /z" /f

Windows Notepad có thể được phục hồi bằng lệnh này (yêu cầu đặc quyền nâng cao) :

reg delete "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /f

Xác nhận kết quả bằng cách mở Regedit và nhìn vào [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe]. Chìa khóa Debugger nên chứa đường dẫn đầy đủ đến Notepad2.exe và bao gồm các dấu /z, ví dụ:

c:\local\bin\Notepad2.exe /z 

Answer 2

Mục đích của việc "gỡ rối" Điều quan trọng là để tự động khởi chạy một trình gỡ lỗi và thông qua dòng lệnh ban đầu để các debugger mong muốn . Nó cũng đặt một lá cờ trên hàm win32 CreateProcess cho biết đây là một phiên gỡ lỗi.

Nó được ngụ ý rằng trình gỡ lỗi sau đó sẽ gọi CreateProcess sau khi sửa đổi các đối số một cách thích hợp.

>notepad.exe "\document1.txt" 

biến thành

>mydebugger.exe notepad.exe "\document1.txt" 

mydebugger sau đó có thể gọi một cái gì đó như thế này:

BOOL res = CreateProcess(NULL, L"notepad.exe \"\\document1.txt\", NULL, NULL, 
          FALSE, cFlags, env, NULL, startupInfo, procInfo&); 

Vì vậy, giải pháp cho lạm dụng khóa registry này là để làm cho debugger giả mạo mà có thể thao tác dòng lệnh theo cách bạn mong muốn. Nó phải là một quá trình đơn giản chỉ phân tích cú pháp dòng lệnh và thay thế notepad.exe bằng notepad2.exe. Sau đó, bạn cần chỉ định sổ đăng ký đó .exe

Answer 3

Notepad Replacer sử dụng kỹ thuật này, nhưng làm cho nó cực kỳ dễ sử dụng và hoạt động với các trình chỉnh sửa không phải là trình gỡ lỗi.

Answer 4

Đối với Notepad ++, để workaround "notepad.exe" được đưa vào dưới dạng tài liệu tạo tệp loạt trình khởi chạy đơn giản (xem câu trả lời của @ Ben vì lý do), rồi trỏ trình gỡ lỗi hình ảnh vào đó (a la @ fenster's câu trả lời).

nppLauncher.bat:

if exist "C:\Program Files\Notepad++\notepad++.exe" start "" "C:\Program Files\Notepad++\notepad++.exe" %2 %3 %4 %5 %6 %7 %8 %9 
if exist "C:\Program Files (x86)\Notepad++\notepad++.exe" start "" "C:\Program Files (x86)\Notepad++\notepad++.exe" %2 %3 %4 %5 %6 %7 %8 %9 

Thêm vào registry:

reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /v "Debugger" /t REG_SZ /d "\"...\path\to\nppLauncher.bat"" /f 

Answer 5

tôi sử dụng các tập tin batch sau để mở emacs thay vì notepad. Tôi cũng đã bao gồm một tham số để bỏ qua nó để tôi vẫn có thể sử dụng notepad khi tôi muốn. ví dụ. chỉnh sửa các tập tin host từ một dấu nhắc lệnh nâng lên:

notepad --NOTEPAD C:\Windows\System32\drivers\etc\hosts 

Đặt một nơi nào đó trên con đường và chỉnh sửa dòng cuối cùng để mở trình soạn thảo văn bản của bạn:

@echo off 
setlocal enabledelayedexpansion 

::Sometimes you really want to use notepad (e.g. edit hosts file from an elevated command prompt) 
if "_%~2_" == "_--NOTEPAD_" (
    set "REALLY_NOTEPAD=TRUE" 
) 

:: For testing calling notepad again without removing debugger registry key 
:: making sure there's not an infinite loop! 
if "_%~2_" == "_STOPSTOPSTOP_" (
start "" echo FAILED TO START NOTEPAD 2 
exit /b 1 
) 

set "NOTEPAD=%~1" 
:: SHIFT command will not affect the value of %* which holds all the original arguments %1 %2 %3 
:: So need to remove notepad from "%*" all params variable 
:: Prepending --START-- in case %NOTEPAD% appears in params 
:: Quotes as NOTEPAD will /sometimes/ be in them in all params 
set "ALL=%*" 
set "ALLPARAMS=--START--%*" 
set "ALLPARAMS=!ALLPARAMS:--START--"%NOTEPAD%"=--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START--%NOTEPAD%=--START--!" 
:: Also remove /multiple/ spaces between NOTEPAD and parameters 
set "ALLPARAMS=!ALLPARAMS:--START-- =--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START-- =--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START-- =!" 
:: Also remove --NOTEPAD if present 
set "ALLPARAMS=!ALLPARAMS:--START----NOTEPAD=--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START-- =--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START-- =--START--!" 
set "ALLPARAMS=!ALLPARAMS:--START-- =!" 
:: and --START--, just in case 
set "ALLPARAMS=!ALLPARAMS:--START--=!" 
IF "_%ALLPARAMS%_" == "__" (
:: Open a scratch buffer in emacs if no params 
    set "ALLPARAMS=**SCRATCH**" 
) 

:: Unicode support (I hope) 
chcp 65001 

::TEST not removing debugger registry key 
::if "_%REALLY_NOTEPAD%_" == "_TRUE_" start "" notepad STOPSTOPSTOP && exit /b 

if "_%REALLY_NOTEPAD%_" == "_TRUE_" (
    reg DELETE "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /v "Debugger" /F 
    start "" notepad !ALLPARAMS! 
    reg ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /v "Debugger" /t REG_SZ /d "%~0" 
    exit /b 0 
) 

C:\path\to\emacs\bin\emacsclientw.exe -na C:\path\to\emacs\bin\runemacs.exe "!ALLPARAMS!" 

bộ nó để thay thế notepad sử dụng lệnh này:

reg ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\notepad.exe" /v "Debugger" /t REG_SZ /d "c:\path\to\wherever\you\savced\script-above.cmd" 

hoặc chỉ cần gọi kịch bản như thế này:

SCRIPT JUNK --NOTEPAD 

nên gọi notepad, nhưng thay thế bằng tập lệnh này sau đó