Đánh dấu Gradle nguồn thư mục như là nguồn thử nghiệm trong IntelliJ

Question

Tôi có một hội nhập thư mục nguồn thử nghiệm thiết lập trong gradle như vậy:

subprojects { 
    apply plugin: 'java' 
    apply plugin: 'idea' 

    sourceCompatibility = 1.8 

    configurations { 
     integrationTestCompile.extendsFrom testCompile 
     integrationTestCompileOnly.extendsFrom integrationTestCompile 
     integrationTestCompileOnly.extendsFrom testCompileOnly 
     integrationTestRuntime.extendsFrom testRuntime 
    } 

    sourceSets { 
     integrationTest { 
      java { 
       compileClasspath += main.output + test.output 
       runtimeClasspath += main.output + test.output 
       srcDir file('src/integrationTest/java') 
      } 
      resources.srcDir file('src/integrationTest/resources') 
     } 
    } 

    task integrationTest(type:Test) { 
     testClassesDir = sourceSets.integrationTest.output.classesDir 
     classpath = sourceSets.integrationTest.runtimeClasspath 
     outputs.upToDateWhen { false } 
    } 
} 

Đối với thực hiện các bài kiểm tra, công trình này hoàn toàn tốt, nhưng nó gây ra vấn đề với thanh tra IntelliJ của , có thể thay đổi hành vi đối với mã thử nghiệm. IntelliJ không nhận ra thư mục nguồn là nguồn thử nghiệm.

tôi đã cố gắng thêm chúng như vậy (bên subprojects):

idea { 
    module { 
     testSourceDirs += file('src/integrationTest/java') 
    } 
} 

nhưng điều đó không giúp gì cả. Tôi cũng đã cố gắng tự đánh dấu chúng là nguồn thử nghiệm (menu ngữ cảnh -> đánh dấu thư mục là -> nguồn kiểm tra gốc), nhưng IntelliJ nhanh chóng ghi đè ngược lại nguồn gốc bình thường.

Làm cách nào để định cấu hình chính xác trong Gradle?

Tôi đang sử dụng IntelliJ 2016/01/03 và Gradle 2.14.1 trên Ubuntu 16,04

Answer 1

Bạn sẽ cần phải chắc chắn nguồn thử nghiệm là nguồn duy nhất cho gói này sau đó

idea { 
    module { 
     sourceDirs -= file('src/integrationTest/java') 
     testSourceDirs += file('src/integrationTest/java') 
    } 
} 

và sau đó bạn sẽ cần phải gradle cleanIdea idea để tạo lại các tệp IntelliJ.

sourceSets { 
    integrationTest { 
     java { 
      compileClasspath += main.output + test.output 
      runtimeClasspath += main.output + test.output 
      srcDir "$projectDir/src/integrationTest/java" 
     } 
     resources.srcDir "$projectDir/src/integrationTest/resources" 
    } 
}