TProc <TObject> để TNotifyEvent

Question

Tiếp tục để post này có chấp nhận câu trả lời vẫn còn rất khó hiểu:

@Button1.OnClick := pPointer(Cardinal(pPointer(procedure (sender: tObject) begin ((sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' end)^) + $0C)^; 

Tôi tự hỏi thời tiết có thể đưa ra một đơn giản nhất và cách thanh lịch giống như:

Button.OnClick := 
        AnonProc2NotifyEvent (
        procedure (Sender: TObject) 
        begin 
         ((Sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' 
        end 
        ); 

như vậy là để đạt được mục đích tương tự và nơi AnonProc2NotifyEvent là phương thức của chủ sở hữu Nút có chữ ký sau:

TOwnerOfButton = class(TForm) 
    Button: TButton; 
    ... 
private 
    ... 
protected 
    function AnonProc2NotifyEvent(aProc: TProc<TObject>): TNotifyEvent; 
public 
    ... 
end; 

Điều đó có khả thi và nếu có thì làm thế nào để thực hiện nó?

Answer 1

này sẽ thực hiện công việc dễ dàng đủ:

type 
    TNotifyEventWrapper = class(TComponent) 
    private 
    FProc: TProc<TObject>; 
    public 
    constructor Create(Owner: TComponent; Proc: TProc<TObject>); 
    published 
    procedure Event(Sender: TObject); 
    end; 

constructor TNotifyEventWrapper.Create(Owner: TComponent; Proc: TProc<TObject>); 
begin 
    inherited Create(Owner); 
    FProc := Proc; 
end; 

procedure TNotifyEventWrapper.Event(Sender: TObject); 
begin 
    FProc(Sender); 
end; 

function AnonProc2NotifyEvent(Owner: TComponent; Proc: TProc<TObject>): TNotifyEvent; 
begin 
    Result := TNotifyEventWrapper.Create(Owner, Proc).Event; 
end; 

Các Owner tham số trong AnonProc2NotifyEvent là cho nên thời gian của đối tượng wrapper có thể được quản lý. Nếu không có thứ gì đó như thế bạn sẽ làm rò rỉ các trường hợp của TNotifyEventWrapper.

Chuyển thành Owner, thành phần mà bạn đang kết nối sự kiện. Ví dụ:

Button1.OnClick := AnonProc2NotifyEvent(
    Button1, 
    procedure(Sender: TObject) 
    begin 
    (Sender as TButton).Caption := 'Clicked'; 
    end 
); 

Vì vậy, khi nút bị hủy, TNotifyEventWrapper cũng sẽ bị hủy. Đối tượng bao bọc phải sống ít nhất chừng nào đối tượng có sự kiện được liên kết. Và do đó, sự lựa chọn của Button1 là chủ sở hữu là tự nhiên và rõ ràng nhất.

Answer 2

Để tham khảo này những gì tôi đang nhận được tại, tôi đã học Barry Kelly 's blog post tham chiếu trong bài trước SO nêu trên và đã đưa ra giải pháp này:

function TMainForm.Proc2NotifyEvent(const aProc: TNotifyReference): TNotifyEvent; 
type 
    TVtable = array[0..3] of Pointer; 
    PVtable = ^TVtable; 
    PPVtable = ^PVtable; 
begin 
    TMethod(Result).Code := PPVtable((@aProc)^)^^[3]; 
    TMethod(Result).Data := Pointer((@aProc)^); 
end; 

Tuy nhiên khó hiểu nhưng encapsuled, vì vậy giảm bớt sự nhiệm vụ của coder so với phương thức ban đầu.

Tôi cố gắng để dọn MethRefToMethPtr và MakeNotify và đặt nó tất cả trong một phương pháp.

Chú ý rằng có (một chút) thay đổi chữ ký của phương pháp, lập luận aProc trở thành const.