delphi Sử dụng các bản ghi làm khóa trong TDictionary

Question

Bạn có thể sử dụng bản ghi làm Giá trị khóa trong TDictionary không? Tôi muốn tìm các đối tượng dựa trên sự kết hợp của chuỗi, số nguyên và số nguyên.

TUserParKey=record 
    App:string; 
    ID:integer; 
    Nr:integer; 
end; 

...

var 
    tmpKey:TUserParKey; 
    tmpObject:TObject; 
begin 
    tmpObject:= TTObject.Create(1); 
    tmpKey.App:='1'; 
    tmpKey.ID :=1; 
    tmpKey.Nr :=1; 

    DTUserPars.Add(tmpKey,tmpObject) 

...

var 
    tmpKey:TUserParKey; 
begin 
    tmpKey.App:='1'; 
    tmpKey.ID :=1; 
    tmpKey.Nr :=1; 

    if not DTUserPars.TryGetValue(tmpKey,Result) then begin 
    result := TTObject.Create(2); 
    end; 

lợi nhuận này đối tượng 2.

Answer 1

Vâng, bạn có thể sử dụng hồ sơ như là chìa khóa trong một TDictionary nhưng bạn nên cung cấp trình duyệt IEqualityComparer của riêng bạn khi tạo từ điển vì từ điển mặc định cho bản ghi chỉ thực hiện so sánh nhị phân câm của ghi lại. Điều này không thành công cho một bản ghi có chứa một chuỗi vì nó chỉ so sánh con trỏ của chuỗi đó có thể khác nhau ngay cả khi chuỗi chứa cùng một giá trị.

Như một Comparer sẽ trông như thế này:

type 
    TUserParKeyComparer = class(TEqualityComparer<TUserParKey>) 
    function Equals(const Left, Right: TUserParKey): Boolean; override; 
    function GetHashCode(const Value: TUserParKey): Integer; override; 
    end; 

function TUserParKeyComparer.Equals(const Left, Right: TUserParKey): Boolean; 
begin 
    Result := (Left.App = Right.App) and (Left.ID = Right.ID) and (Left.Nr = Right.Nr); 
end; 

function TUserParKeyComparer.GetHashCode(const Value: TUserParKey): Integer; 
begin 
    Result := BobJenkinsHash(PChar(Value.App)^, Length(Value.App) * SizeOf(Char), 0); 
    Result := BobJenkinsHash(Value.ID, SizeOf(Integer), Result); 
    Result := BobJenkinsHash(Value.Nr, SizeOf(Integer), Result); 
end;