Mở rộng CamelCase trong Vim như Intellij Idea?

Question

Trong Intellij Idea, có một tính năng. Giả sử tôi đã sử dụng biến số myCamelCase ở đâu đó trong mã của tôi. Sau đó, nếu tôi nhập mCC và nhấn Ctrl - Nhập hoặc một số tổ hợp phím như vậy, nó sẽ mở rộng thành myCamelCase. Có cái gì đó tương tự trong Vim?

Answer 1

Được rồi, hãy tha thứ cho tôi để trả lời hai lần, nhưng vì lần thử đầu tiên của tôi bị mất điểm, tôi sẽ có một bước khác. Điều này phức tạp hơn tôi nghĩ, nhưng có thể không phức tạp như tôi đã làm nó (!).

Điều này hiện được sửa đổi để đề xuất tất cả các tên biến phù hợp.

Trước hết, đây là một chức năng để tạo ra các 'MCC' viết tắt từ chuỗi các 'myCamelCase':

function! Camel_Initials(camel) 
    let first_char = matchstr(a:camel,"^.") 
    let other_char = substitute(a:camel,"\\U","","g") 
    return first_char . other_char 
endfunction 

Bây giờ, đây là một chức năng mà phải mất một chữ viết tắt ('MCC') và quét bộ đệm hiện tại (lùi từ dòng hiện tại) cho "từ" có chữ viết tắt này. Một danh sách tất cả các trận đấu sẽ được trả về:

function! Expand_Camel_Initials(abbrev) 
    let winview=winsaveview() 
    let candidate=a:abbrev 
    let matches=[] 
    try 
     let resline = line(".") 
     while resline >= 1 
      let sstr = '\<' . matchstr(a:abbrev,"^.") . '[a-zA-Z]*\>' 
      keepjumps let resline=search(sstr,"bW") 
      let candidate=expand("<cword>") 
      if candidate != a:abbrev && Camel_Initials(candidate) == a:abbrev 
       call add(matches, candidate) 
      endif 
     endwhile 
    finally 
     call winrestview(winview) 
     if len(matches) == 0 
      echo "No expansion found" 
     endif 
     return sort(candidate) 
    endtry 
endfunction 

Tiếp theo, đây là một chức năng tùy chỉnh hoàn thành mà đọc từ dưới con trỏ và gợi ý các trận đấu được trả về bởi các chức năng trên:

function! Camel_Complete(findstart, base) 
    if a:findstart 
     let line = getline('.') 
     let start = col('.') - 1 
     while start > 0 && line[start - 1] =~ '[A-Za-z_]' 
      let start -= 1 
     endwhile 
     return start 
    else 
     return Expand_Camel_Initials(a:base) 
    endif 
endfunction 

Để tận dụng điều này, bạn phải xác định "completefunc":

setlocal completefunc=Camel_Complete 

Để sử dụng chèn chế độ hoàn thành, loại CTRL-XCTRL-U, nhưng tôi thường bản đồ này để CTRL-L:

inoremap <c-l> <c-x><c-u> 

Với mã này trong vimrc của bạn, bạn nên tìm dược đưa vào mCC tiếp theo CTRL-L sẽ thực hiện thay thế dự kiến. Nếu không tìm thấy mở rộng phù hợp, chữ viết tắt sẽ không thay đổi.

Mã không chặt chẽ, nhưng nó hoạt động trong tất cả các trường hợp đơn giản mà tôi đã thử nghiệm. Hy vọng nó giúp. Hãy cho tôi biết nếu có bất cứ điều gì cần làm sáng tỏ.

Answer 2

Có một plugin cho điều này trong Vim gọi là vim-abolish. Sử dụng bản đồ crc để mở rộng thành vỏ lạc đà.