Làm cách nào để tìm kiếm bộ đệm mở trong Vim?

Question

Tôi muốn tìm kiếm văn bản trong tất cả các tệp hiện đang mở trong vim và hiển thị tất cả kết quả ở một nơi duy nhất. Có hai vấn đề, tôi đoán:

• tôi không thể vượt qua danh sách các tập tin mở để :grep/:vim, đặc biệt là tên của file mà không phải là trên đĩa;
• Kết quả của :grep -C 1 text không có vẻ tốt trong cửa sổ quickfix.

Dưới đây là một ví dụ tốt đẹp của việc tìm kiếm tập tin nhiều trong Sublime Văn bản 2:

Bất kỳ ý tưởng?

Answer 1

Hoặc

:bufdo vimgrepadd threading % | copen 

Cửa sổ QuickFix có thể không nhìn tốt cho bạn, nhưng nó là một địa ngục của rất nhiều chức năng hơn so với "bảng kết quả" ST2 nếu chỉ vì bạn có thể giữ nó mở và có thể nhìn thấy trong khi nhảy đến các địa điểm và tương tác với nó nếu nó không có ở đó.

Answer 2

ack và Ack.vim xử lý vấn đề này một cách đẹp mắt. Bạn cũng có thể sử dụng :help :vimgrep. Ví dụ:

:bufdo AckAdd -n threading 

sẽ tạo cửa sổ quickfix đẹp cho phép bạn chuyển vị trí con trỏ.

Answer 3

tôi đã thực hiện chức năng này trong một thời gian dài trước đây, và tôi đoán nó có thể không phải là sạch nhất các giải pháp, nhưng nó đã được hữu ích cho tôi:

" Looks for a pattern in the open buffers. 
" If list == 'c' then put results in the quickfix list. 
" If list == 'l' then put results in the location list. 
function! GrepBuffers(pattern, list) 
    let str = '' 

    if (a:list == 'l') 
     let str = 'l' 
    endif 

    let str = str . 'vimgrep /' . a:pattern . '/' 

    for i in range(1, bufnr('$')) 
     let str = str . ' ' . fnameescape(bufname(i)) 
    endfor 

    execute str 
    execute a:list . 'w' 
endfunction 

" :GrepBuffers('pattern') puts results into the quickfix list 
command! -nargs=1 GrepBuffers call GrepBuffers(<args>, 'c') 

" :GrepBuffersL('pattern') puts results into the location list 
command! -nargs=1 GrepBuffersL call GrepBuffers(<args>, 'l') 

Answer 4

Giống như câu trả lời của Waz, tôi đã viết lệnh tùy chỉnh cho điều đó, được xuất bản trong số GrepCommands plugin của tôi. Nó cho phép tìm kiếm trên bộ đệm (:BufGrep), cửa sổ hiển thị (:WinGrep), tab và đối số.

(Nhưng giống như tất cả các câu trả lời khác, nó không xử lý bộ đệm giấu tên được nêu ra.)

Answer 5

Một cải tiến (trên steroid) phiên bản của câu trả lời Waz, với tìm kiếm đệm tốt hơn và xử lý trường hợp đặc biệt, có thể được tìm thấy dưới đây (Những người kiểm duyệt sẽ không cho phép tôi cập nhật câu trả lời của Waz nữa: D). Một phiên bản được tô điểm nhiều hơn với các liên kết cho các phím mũi tên để điều hướng danh sách QuickFix và F3 để đóng cửa sổ QuickFix có thể tìm thấy tại đây: https://pastebin.com/5AfbY8sm (Khi tôi cảm thấy như tìm cách tạo plugin, tôi sẽ cập nhật câu trả lời này. muốn xúc chia sẻ nó cho bây giờ)

" Looks for a pattern in the buffers. 
" Usage :GrepBuffers [pattern] [matchCase] [matchWholeWord] [prefix] 
" If pattern is not specified then usage instructions will get printed. 
" If matchCase = '1' then exclude matches that do not have the same case. If matchCase = '0' then ignore case. 
" If prefix == 'c' then put results in the QuickFix list. If prefix == 'l' then put results in the location list for the current window. 
function! s:GrepBuffers(...) 
    if a:0 > 4 
     throw "Too many arguments" 
    endif 

    if a:0 >= 1 
     let l:pattern = a:1 
    else 
     echo 'Usage :GrepBuffers [pattern] [matchCase] [matchWholeWord] [prefix]' 
     return 
    endif 

    let l:matchCase = 0 
    if a:0 >= 2 
     if a:2 !~ '^\d\+$' || a:2 > 1 || a:2 < 0 
      throw "ArgumentException: matchCase value '" . a:2 . "' is not in the bounds [0,1]." 
     endif 
     let l:matchCase = a:2 
    endif 

    let l:matchWholeWord = 0 
    if a:0 >= 3 
     if a:3 !~ '^\d\+$' || a:3 > 1 || a:3 < 0 
      throw "ArgumentException: matchWholeWord value '" . a:3 . "' is not in the bounds [0,1]." 
     endif 
     let l:matchWholeWord = a:3 
    endif 

    let l:prefix = 'c' 
    if a:0 >= 4 
     if a:4 != 'c' && a:4 != 'l' 
      throw "ArgumentException: prefix value '" . a:4 . "' is not 'c' or 'l'." 
     endif 
     let l:prefix = a:4 
    endif 

    let ignorecase = &ignorecase 
    let &ignorecase = l:matchCase == 0 
    try 
     if l:prefix == 'c' 
      let l:vimgrep = 'vimgrep' 
     elseif l:prefix == 'l' 
      let l:vimgrep = 'lvimgrep' 
     endif 

     if l:matchWholeWord 
      let l:pattern = '\<' . l:pattern . '\>' 
     endif 

     let str = 'silent ' . l:vimgrep . ' /' . l:pattern . '/' 

     for buf in getbufinfo() 
      if buflisted(buf.bufnr) " Skips unlisted buffers because they are not used for normal editing 
       if !bufexists(buf.bufnr) 
        throw 'Buffer does not exist: "' . buf.bufnr . '"' 
       elseif empty(bufname(buf.bufnr)) && getbufvar(buf.bufnr, '&buftype') != 'quickfix' 
        if len(getbufline(buf.bufnr, '2')) != 0 || strlen(getbufline(buf.bufnr, '1')[0]) != 0 
         echohl warningmsg | echomsg 'Skipping unnamed buffer: [' . buf.bufnr . ']' | echohl normal 
        endif 
       else 
        let str = str . ' ' . fnameescape(bufname(buf.bufnr)) 
       endif 
      endif 
     endfor 

     try 
      execute str 
     catch /^Vim\%((\a\+)\)\=:E\%(683\|480\):/ "E683: File name missing or invalid pattern --- E480: No match: 
      " How do you want to handle this exception? 
      echoerr v:exception 
      return 
     endtry 

     execute l:prefix . 'window' 
    "catch /.*/ 
    finally 
     let &ignorecase = ignorecase 
    endtry 
endfunction