sắp xếp theo mmyy (tháng và năm)

Question

Tôi đang tìm một mô-đun logic (không phải mô-đun bổ sung) để sắp xếp theo định dạng như vậy. Tôi có một danh sách các chuỗi trông giống như:

asdadasBBBsfasdasdas-0112 
asdanfnfnfnfnf222ads-1210 

, vv tôi không thể chỉ sắp xếp theo các con số, bởi vì, ví dụ: 812> 113 (812 = Tháng Tám 2012, 113 = tháng Giêng năm 2013, vì vậy không chính xác của nó)

bất kỳ chiến lược nào tốt?

cảm ơn,

Answer 1

Một schwartzian chuyển đổi sẽ là một sự lãng phí rất lớn ở đây. Cấu trúc tương tự này có tên tôi không bao giờ có thể nhớ sẽ là cách tốt hơn.

my @sorted = 
    map substr($_, 4), 
    sort 
    map substr($_, -2) . substr($_, -4, 2) . $_, 
     @unsorted; 

Sử dụng các nhà điều hành trận đấu thay vì substr:

my @sorted = 
    map substr($_, 4), 
    sort 
    map { /(..)(..)\z/s; $2.$1.$_ } 
     @unsorted; 

Answer 2

Sử dụng chức năng sắp xếp mà nhìn vào năm đầu tiên, và sau đó ngày:

sub mmyy_sorter { 

    my $a_yy = substr($a, -2); 
    my $b_yy = substr($b, -2); 

    my $a_mm = substr($a, -4, 2); 
    my $b_mm = substr($b, -4, 2); 

    return ($a_yy cmp $b_yy) || ($a_mm cmp $b_mm); 
} 

my @sorted = sort mmyy_sorter @myarray; 

NB: đây là kỹ thuật không hiệu quả như nó có thể là vì nó có để tính toán lại các trường con tháng và năm cho mỗi lần so sánh, không chỉ một lần cho mỗi mục trong mảng.

Cũng có thể tận dụng lợi thế của chuyển đổi loại tự động của Perl và sử dụng toán tử <=> thay cho cmp, vì tất cả các giá trị thực sự đại diện cho các số.

Answer 3

Điều gì về việc làm lại thành tháng? Ví dụ:

812 = 12 * 12 + 8

113 = 13 * 12 + 1

Bạn có thể bật năm vào tháng và nó sẽ được tốt. Để chọn số bạn có thể sử dụng regex.

Answer 4

Làm thế nào về Schwartzian transform:

#!/usr/bin/perl 
use strict; 
use warnings; 
use Data::Dump qw(dump); 

my @list = (
    'asdadasBBBsfasdasdas-0112', 
    'asdanfnfnfnfnf222ads-1210', 
    'asdanfnfnfnfnf222ads-1211', 
    'asdanfnfnfnfnf222ads-1010', 
    'asdanfnfnfnfnf222ads-1011', 
); 

my @sorted = 
    map { $_->[0] } 
    sort { $a->[1] <=> $b->[1] or $a->[2] <=> $b->[2] } 
    map { /-(\d\d)(\d\d)$/; [$_, $2, $1] } @list; 
dump @sorted; 

đầu ra:

(
    "asdanfnfnfnfnf222ads-1010", 
    "asdanfnfnfnfnf222ads-1210", 
    "asdanfnfnfnfnf222ads-1011", 
    "asdanfnfnfnfnf222ads-1211", 
    "asdadasBBBsfasdasdas-0112", 
) 

Answer 5

Nhờ @ M42 cho dữ liệu mẫu.

use strict; 
use warnings; 
use feature 'say'; 

my @list = (
    'asdadasBBBsfasdasdas-0112', 
    'asdanfnfnfnfnf222ads-1210', 
    'asdanfnfnfnfnf222ads-1211', 
    'asdanfnfnfnfnf222ads-1010', 
    'asdanfnfnfnfnf222ads-1011', 
); 

my @sorted = sort { 
    my ($aa, $bb) = map { /(..)(..)\z/ and $2.$1 } $a, $b; 
    $aa <=> $bb; 
} @list; 

say for @sorted; 

đầu ra

asdanfnfnfnfnf222ads-1010 
asdanfnfnfnfnf222ads-1210 
asdanfnfnfnfnf222ads-1011 
asdanfnfnfnfnf222ads-1211 
asdadasBBBsfasdasdas-0112