XPath chọn nút với namespace

Question

Its a .vbproj và trông như thế này

<Project DefaultTargets="Build" xmlns="http://schemas.microsoft.com/developer/msbuild/2003"> 
    <PropertyGroup> 
     <ProjectGuid>15a7ee82-9020-4fda-a7fb-85a61664692d</ProjectGuid> 

tất cả tôi muốn nhận được các ProjectGuid nhưng nó không hoạt động khi một namespace là có ...

Dim xmlDoc As New XmlDocument() 
Dim filePath As String = Path.Combine(mDirectory, name + "\" + name + ".vbproj") 
xmlDoc.Load(filePath) 
Dim value As Object = xmlDoc.SelectNodes("/Project/PropertyGroup/ProjectGuid") 

Tôi có thể làm gì để sửa lỗi này?

Answer 1

Cách tốt nhất để làm những việc như thế này (IMHO) là tạo trình quản lý không gian tên. Điều này có thể được sử dụng để gọi SelectNodes để cho biết URL không gian tên nào được kết nối với các tiền tố nào. Tôi thường thiết lập một thuộc tính tĩnh mà trả về một thể hiện đầy đủ như thế này (C nó #, bạn sẽ phải dịch):

private static XmlNamespaceManager _nsMgr; 
public static XmlNamespaceManager NsMgr 
{ 
    get 
    { 
    if (_nsMgr == null) 
    { 
     _nsMgr = new XmlNamespaceManager(new NameTable()); 
     _nsMgr.AddNamespace("msb", "http://schemas.microsoft.com/developer/msbuild/2003"); 
    } 
    return _nsMgr; 
    } 
} 

tôi chỉ bao gồm một không gian tên ở đây, nhưng bạn có thể có nhiều. Sau đó, bạn có thể chọn từ tài liệu như sau:

Dim value As Object = xmlDoc.SelectNodes("/msb:Project/msb:PropertyGroup/msb:ProjectGuid", NsMgr) 

Lưu ý rằng tất cả các phần tử đều nằm trong không gian tên được chỉ định.

Answer 2

Tại sao không sử dụng // để bỏ qua không gian tên:

Dim value As Object = xmlDoc.SelectNodes("//ProjectGuid") 

// hoạt động như thẻ hoang dã để làm theo thông qua tất cả mọi thứ giữa gốc và tên nút tiếp theo quy định (ví dụ ProjectGuid)

Answer 3

tôi 'lẽ muốn được nghiêng đi với giải pháp namespace * Bartek, nhưng một giải pháp xpath chung là:

//*[local-name()='ProjectGuid']

** vì câu trả lời của Bartek đã biến mất, tôi khuyên Teun (thực sự là kỹ lưỡng hơn) *

Answer 4

Sự cố này đã ở đây severaltimesalready.

Dù bạn làm việc với các biểu thức XPath namespace-agnostic (không khuyến khích cho sự vụng về của mình và tiềm năng cho các trận đấu dương tính giả - <msb:ProjectGuid> và <foo:ProjectGuid> là như nhau cho biểu thức này):

//*[local-name() = 'ProjectGuid']

hoặc bạn làm đúng các điều và sử dụng một XmlNamespaceManager để đăng ký namespace URI để bạn có thể bao gồm một tiền tố namespace trong XPath của bạn:

Dim xmlDoc As New XmlDocument() 
xmlDoc.Load(Path.Combine(mDirectory, name, name + ".vbproj")) 

Dim nsmgr As New XmlNamespaceManager(xmlDoc.NameTable) 
nsmgr.AddNamespace("msb", "http://schemas.microsoft.com/developer/msbuild/2003") 

Dim xpath As String = "/msb:Project/msb:PropertyGroup/msb:ProjectGuid" 
Dim value As Object = xmlDoc.SelectNodes(xpath, nsmgr) 

Answer 5

bạn chỉ cần đăng ký này không gian tên XML và associ ăn với một tiền tố, để làm cho truy vấn hoạt động. Tạo và vượt qua một người quản lý không gian tên như tham số thứ hai khi lựa chọn các nút:

Dim ns As New XmlNamespaceManager (xmlDoc.NameTable) 
ns.AddNamespace ("msbuild", "http://schemas.microsoft.com/developer/msbuild/2003") 
Dim value As Object = xmlDoc.SelectNodes("/msbuild:Project/msbuild:PropertyGroup/msbuild:ProjectGuid", ns) 

Answer 6

Một cách là sử dụng phần mở rộng + NameSpaceManager.
Mã bằng VB nhưng thực sự dễ dàng dịch sang C#.

Imports System.Xml 
Imports System.Runtime.CompilerServices 

Public Module Extensions_XmlHelper 

    'XmlDocument Extension for SelectSingleNode 
    <Extension()> 
    Public Function _SelectSingleNode(ByVal XmlDoc As XmlDocument, xpath As String) As XmlNode 
     If XmlDoc Is Nothing Then Return Nothing 

     Dim nsMgr As XmlNamespaceManager = GetDefaultXmlNamespaceManager(XmlDoc, "x") 
     Return XmlDoc.SelectSingleNode(GetNewXPath(xpath, "x"), nsMgr) 
    End Function 

    'XmlDocument Extension for SelectNodes 
    <Extension()> 
    Public Function _SelectNodes(ByVal XmlDoc As XmlDocument, xpath As String) As XmlNodeList 
     If XmlDoc Is Nothing Then Return Nothing 

     Dim nsMgr As XmlNamespaceManager = GetDefaultXmlNamespaceManager(XmlDoc, "x") 
     Return XmlDoc.SelectNodes(GetNewXPath(xpath, "x"), nsMgr) 
    End Function 


    Private Function GetDefaultXmlNamespaceManager(ByVal XmlDoc As XmlDocument, DefaultNamespacePrefix As String) As XmlNamespaceManager 
     Dim nsMgr As New XmlNamespaceManager(XmlDoc.NameTable) 
     nsMgr.AddNamespace(DefaultNamespacePrefix, XmlDoc.DocumentElement.NamespaceURI) 
     Return nsMgr 
    End Function 

    Private Function GetNewXPath(xpath As String, DefaultNamespacePrefix As String) As String 
     'Methode 1: The easy way 
     Return xpath.Replace("/", "/" + DefaultNamespacePrefix + ":") 

     ''Methode 2: Does not change the nodes with existing namespace prefix 
     'Dim Nodes() As String = xpath.Split("/"c) 
     'For i As Integer = 0 To Nodes.Length - 1 
     ' 'If xpath starts with "/", don't add DefaultNamespacePrefix to the first empty node (before "/") 
     ' If String.IsNullOrEmpty(Nodes(i)) Then Continue For 
     ' 'Ignore existing namespaces prefixes 
     ' If Nodes(i).Contains(":"c) Then Continue For 
     ' 'Add DefaultNamespacePrefix 
     ' Nodes(i) = DefaultNamespacePrefix + ":" + Nodes(i) 
     'Next 
     ''Create and return then new xpath 
     'Return String.Join("/", Nodes) 
    End Function 

End Module 

Và để sử dụng nó:

Imports Extensions_XmlHelper 

...... 
Dim FileXMLTextReader As New XmlTextReader(".....") 
FileXMLTextReader.WhitespaceHandling = WhitespaceHandling.None 
Dim xmlDoc As XmlDocument = xmlDoc.Load(FileXMLTextReader) 
FileXMLTextReader.Close() 
...... 
Dim MyNode As XmlNode = xmlDoc._SelectSingleNode("/Document/FirstLevelNode/SecondLevelNode") 

Dim MyNode As XmlNodeList = xmlDoc._SelectNodes("/Document/FirstLevelNode/SecondLevelNode") 

......