Truy vấn đường dẫn thuộc tính SPARQL với các thuộc tính tùy ý

Question

SPARQL property path truy vấn có độ dài tùy ý yêu cầu sử dụng các thuộc tính cụ thể. Tôi muốn truy vấn và tìm bất kỳ đường dẫn nào bắt đầu từ một tài nguyên và kết thúc bằng một tài nguyên khác. Ví dụ:

SELECT ?p 
WHERE { :startNode ?p* :endNode } 

trong đó ?p* chỉ định đường dẫn. Có cách nào để làm điều này?

Answer 1

Bạn nói đúng là bạn không thể sử dụng các biến trong biểu thức đường dẫn thuộc tính. Tuy nhiên, có một vài điều mà bạn có thể có thể giúp bạn.

Một đại diện để kiểm tra liệu một con đường tồn tại

Bạn có thể sử dụng một ký tự đại diện bằng cách lấy phân ly của nó và phủ định của nó, vì vậy bạn có thể thực hiện một truy vấn đơn giản để kiểm tra liệu có một con đường kết nối hai nguồn:

<source> (<>|!<>)* <target> 

Nếu bạn có một tiền tố : xác định, mà có thể còn ngắn hơn, vì : là một IRI hợp lệ:

<source> (:|!:)* <target> 

Nếu có một con đường (hoặc nhiều đường dẫn) giữa hai nút, bạn có thể chia nó lên bằng con đường tự đại diện tham gia của ?p, và do đó tất cả các ?p s mà là trên con đường:

<source> (:|!:)* ?x . 
?x ?p ?y . 
?y (:|!:)* <target> . 

Bạn có thể làm cho điều đó thậm chí ngắn hơn, tôi nghĩ rằng, bằng cách sử dụng các nút trống thay vì ?x và ?y:

<source> (:|!:)* [ ?p [ (:|!:)* <target> ] ] 

(đó thể không làm việc, ngươi gh. Tôi dường như nhớ lại ngữ pháp thực sự không cho phép đường dẫn thuộc tính ở một số nơi trong các nút trống. Tôi không chắc chắn.)

Đối với một con đường duy nhất, có được tài sản và vị trí, sau đó group_concat

Bây giờ, trong trường hợp đó chỉ có một con đường giữa hai nguồn lực, thậm chí bạn có thể nhận được các thuộc tính cùng mà đường dẫn, cùng với vị trí của họ. Bạn có thể đặt hàng bởi các vị trí đó, và sau đó sử dụng một nhóm bằng cách nối các thuộc tính theo thứ tự thành một chuỗi đơn. Điều này có lẽ là dễ nhất để xem với một ví dụ. Giả sử bạn đã có các dữ liệu sau đó có một con đường duy nhất :a-:d:

@prefix : <urn:ex:> . 

:a :p1 :b . 
:b :p2 :c . 
:c :p3 :d . 

Sau đó, bạn có thể sử dụng một truy vấn như thế này để có được mỗi tài sản trong đường dẫn và vị trí của nó. (Điều này chỉ hoạt động nếu có một con đường duy nhất, mặc dù. Xem câu trả lời của tôi để Is it possible to get the position of an element in an RDF Collection in SPARQL? cho một chút thêm về cách làm việc này.)

prefix : <urn:ex:> 

select ?p (count(?mid) as ?pos) where { 
    :a (:|!:)* ?mid . 
    ?mid (:|!:)* ?x . 
    ?x ?p ?y. 
    ?y (:|!:)* :d 
} 
group by ?x ?p ?y 

------------- 
| p | pos | 
============= 
| :p2 | 2 | 
| :p1 | 1 | 
| :p3 | 3 | 
------------- 

Bây giờ, nếu bạn đặt hàng những kết quả theo ?pos và quấn rằng truy vấn trong một truy vấn khác, sau đó bạn có thể sử dụng group_concat trên ?p để nhận được một chuỗi các thuộc tính theo thứ tự. (Thứ tự đang được bảo quản không được bảo đảm, nhưng đó là hành vi khá phổ biến.Xem câu trả lời của tôi để obtain the matrix in protege cho một ví dụ về cách kỹ thuật này hoạt động, và my answer to Ordering in GROUP_CONCAT in SPARQL 1.1 để thảo luận về lý do tại sao nó không được đảm bảo.)

prefix : <urn:ex:> 

select (group_concat(concat('<',str(?p),'>');separator=' ') as ?path) { 
    select ?p (count(?mid) as ?pos) where { 
    :a (:|!:)* ?mid . 
    ?mid (:|!:)* ?x . 
    ?x ?p ?y. 
    ?y (:|!:)* :d 
    } 
    group by ?x ?p ?y 
    order by ?pos 
} 

----------------------------------------- 
| path         | 
========================================= 
| "<urn:ex:p1> <urn:ex:p2> <urn:ex:p3>" | 
-----------------------------------------