Làm cách nào để tạo biến ký tự bằng giá trị được định dạng của biến số cho các định dạng SAS tùy ý?

Question

Nếu tôi có biến số có định dạng, có cách nào để nhận giá trị được định dạng dưới dạng biến ký tự không?

ví dụ: Tôi muốn viết một cái gì đó như sau để in 10/06/2009 vào màn hình nhưng không có chức năng putformatted().

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = putformatted(i); /* How should I write this? */ 
    put i_formatted; 
run; 

(Rõ ràng là tôi có thể viết put(i, ddmmyy10.), nhưng mã của tôi cần phải làm việc cho bất cứ định dạng i xảy ra để có.)

Answer 1

Các VVALUE chức năng định dạng các biến được truyền cho nó bằng cách sử dụng định dạng liên quan đến việc thay đổi. Dưới đây là các mã sử dụng VVALUE:

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = vvalue(i); 
    put i_formatted; 
run; 

Trong khi cmjohns giải pháp là nhanh hơn một chút so với mã này, mã này là đơn giản bởi vì không có macro có liên quan.

Answer 2

tôi có thể làm điều này với mã vĩ mô và sashelp.vcolumn nhưng đó là một chút khó sử dụng.

proc sql noprint; 
    select trim(left(format)) into :format 
    from sashelp.vcolumn 
    where libname eq 'WORK' and memname eq 'TEST'; 
run; 

data test2; 
    set test; 
    i_formatted = put(i, &format); 
    put i_formatted; 
run; 

Answer 3

Điều này dường như hoạt động đối với cặp vợ chồng mà tôi đã thử. Tôi đã sử dụng VARFMT và một hàm macro để truy lục định dạng của biến đã cho.

data test; 
    format i ddmmyy10. b comma12.; 
    i = "10JUN2009"d; 
    b = 123405321; 
run; 


%macro varlabel(variable) ; 
    %let dsid=%sysfunc(open(&SYSLAST.)) ; 
    %let varnum=%sysfunc(varnum(&dsid,&variable)) ; 
    %let fmt=%sysfunc(varfmt(&dsid,&varnum)); 
    %let dsid=%sysfunc(close(&dsid)) ; 
    &fmt 
%mend varlabel; 

data test2; 
    set test; 
    i_formatted = put(i, %varlabel(i)); 
    b_formatted = put(b, %varlabel(b)); 
    put i_formatted=; 
    put b_formatted=; 
run; 

này đã cho tôi:

i_formatted=10/06/2009 
b_formatted=123,405,321 

Answer 4

Sử dụng vformat() chức năng.

/* test data */ 
data test; 
    i = "10jun2009"d; 
    format i ddmmyy10.; 
run; 

/* print out the value using the associated format */ 
data _null_; 
    set test; 
    i_formatted = putn(i, vformat(i)); 
    put i_formatted=; 
run; 
/* on log 
i_formatted=10/06/2099 
*/ 

Answer 5

Có, có hàm putformatted(). Trong thực tế, có hai: putc() và putn(). Putc xử lý các định dạng ký tự, số putn(). Mã của bạn sẽ cần phải nhìn vào tên định dạng (tất cả và chỉ các định dạng ký tự bắt đầu bằng "$") để xác định sử dụng. Đây là cú pháp của putc (từ sự giúp đỡ tương tác):

PUTC(source, format.<,w>) 

Arguments

source 
is the SAS expression to which you want to apply the format. 

format. 
is an expression that contains the character format you want to apply to source. 

w 
specifies a width to apply to the format. 

Interaction: If you specify a width here, it overrides any width specification 
in the format.