Làm cách nào để nhập mật khẩu bằng Perl và thay thế các ký tự bằng '*'?

Question

Tôi có một tập lệnh Perl yêu cầu người dùng nhập mật khẩu. Làm thế nào tôi có thể chỉ echo '*' thay cho ký tự mà người dùng gõ, khi họ gõ nó?

Tôi đang sử dụng Windows XP/Vista.

Answer 1

Bạn có thể chơi với thuật ngữ :: ReadKey. Đây là một ví dụ rất đơn giản, với một số phát hiện cho phím xóa lùi và xóa. Tôi đã thử nghiệm nó trên Mac OS X 10.5 nhưng theo ReadKey manual nó sẽ làm việc trong Windows. Các manual chỉ ra rằng trong Windows sử dụng đọc không chặn (ReadKey(-1)) sẽ thất bại. Đó là lý do tại sao tôi đang sử dụng ReadKey (0) về cơ bản là getc (nhiều hơn trên getc trong libc manual).

#!/usr/bin/perl                                                 

use strict;                                                  
use warnings;                                                 
use Term::ReadKey;                                                

my $key = 0;                                                 
my $password = "";                                                

print "\nPlease input your password: ";                                           

# Start reading the keys                                              
ReadMode(4); #Disable the control keys                                           
while(ord($key = ReadKey(0)) != 10)                                            
# This will continue until the Enter key is pressed (decimal value of 10)                                  
{                                                    
    # For all value of ord($key) see http://www.asciitable.com/                                     
    if(ord($key) == 127 || ord($key) == 8) {                                         
     # DEL/Backspace was pressed                                            
     #1. Remove the last char from the password                                        
     chop($password);                                              
     #2 move the cursor back by one, print a blank character, move the cursor back by one                             
     print "\b \b";                                               
    } elsif(ord($key) < 32) {                                             
     # Do nothing with these control characters                                        
    } else {                                                 
     $password = $password.$key;                                            
     print "*(".ord($key).")";                                            
    }                                                   
}                                                    
ReadMode(0); #Reset the terminal once we are done                                        
print "\n\nYour super secret password is: $password\n"; 

Answer 2

Bạn đã thử lưu trữ chuỗi (để chương trình của bạn vẫn có thể đọc được) và tìm hiểu độ dài của nó rồi tạo chuỗi có cùng độ dài, nhưng chỉ sử dụng '*'?

Answer 3

Bạn nên xem Term::ReadKey hoặc Win32::Console. Bạn có thể sử dụng các mô-đun đó để đọc các nét chính và phát ra '*' hoặc bất kỳ từ nào.

Answer 4

Trước đây tôi đã sử dụng IO::Prompt cho việc này.

use IO::Prompt; 
my $password = prompt('Password:', -e => '*'); 
print "$password\n"; 

Answer 5

Nếu bạn không muốn sử dụng bất kỳ gói ... Chỉ dành cho UNIX

system('stty','-echo'); 
chop($password=<STDIN>); 
system('stty','echo'); 

Answer 6

xây dựng trên chương trình Pierr-Luc, chỉ cần bổ sung một số điều khiển trên backslashes. Với điều này, bạn không thể tiếp tục nhấn dấu gạch chéo ngược mãi mãi:

sub passwordDisplay() { 
    my $password = ""; 
    # Start reading the keys 
    ReadMode(4); #Disable the control keys 
    my $count = 0; 
    while(ord($key = ReadKey(0)) != 10) { 
      # This will continue until the Enter key is pressed (decimal value of 10) 
      # For all value of ord($key) see http://www.asciitable.com/ 
      if(ord($key) == 127 || ord($key) == 8) { 
        # DEL/Backspace was pressed 
        if ($count > 0) { 
          $count--; 
          #1. Remove the last char from the password 
          chop($password); 
          #2 move the cursor back by one, print a blank character, move the cursor back by one 
          print "\b \b"; 
        } 
      } 
      elsif(ord($key) >= 32) { 
        $count++; 
        $password = $password.$key; 
        print "*"; 
      } 
    } 
    ReadMode(0); #Reset the terminal once we are done 
    return $password; 
}