Làm thế nào để bạn redimension một mảng trong VBA?

Question

Tôi đang cố gắng rediminsion một mảng trong MS Access VBA. Cách hiệu quả nhất để làm điều này là gì?

Answer 1

Làm thế nào về ...

này sẽ bảo toàn dữ liệu đã có trong myArray

Redim Preserve MyArray(15) 

này sẽ xóa bất kỳ dữ liệu trước đó tồn tại trong myArray

Redim MyArray(15) 

Answer 2

Nhất hiệu quả cách để redimension một mảng là để giới hạn số lần bạn thay đổi kích thước mảng đó. Mỗi khi bạn thay đổi kích cỡ mảng VB sẽ lấy toàn bộ mảng và sao chép nó, lãng phí thời gian và bộ nhớ.

Nếu bạn không biết kích thước mảng của mình tại thời điểm phát triển, bạn nên thực hiện phỏng đoán tốt nhất với kích thước tối đa của mảng, sau đó điền vào mảng. Sau khi điền xong mảng, bạn có thể thay đổi kích thước của nó xuống kích thước chính xác.

Trong các vòng, thường là tốt nhất để thực hiện dự đoán này bằng cách tăng gấp đôi kích thước của mảng hiện tại khi bạn hết dung lượng. Bạn có thể thấy điều này trong hành động dưới đây với RedimTestA() thay đổi kích thước mảng mỗi lần lặp (1.000.000 lần) và RedimTestB() chỉ thay đổi kích thước đôi khi (22 lần).

Trên máy tính xách tay của tôi RedimTestA() mất 3,93 giây và RedimTestB() mất 0,41 giây.

Option Explicit 

Sub RedimTest() 
    Dim tA, tB As Single 
    tA = RedimTestA(1000000) 
    tB = RedimTestB(1000000) 

    MsgBox "Test A takes : " & tA & ", and Test B takes : " & tB 

End Sub 


Function RedimTestA(iterations As Long) As Single 
    Dim t As Single 
    Dim i As Long 
    Dim aryString() As String 
    Dim myString As String 

    t = Timer 
    Do While i <= iterations 
    ReDim Preserve aryString(i) As String 
    aryString(i) = "ABCEFG123" 
    i = i + 1 
    Loop 
    RedimTestA = Timer - t 

End Function 


Function RedimTestB(iterations As Long) As Single 
    Dim t As Single 
    Dim i As Long 
    Dim aryString() As String 
    Dim myString As String 

    t = Timer 

    ReDim aryString(0) As String 
    Do While i <= iterations 
    If i >= UBound(aryString) Then 
     ReDim Preserve aryString(i * 2) As String 
    End If 

    aryString(i) = "ABCEFG123" 
    i = i + 1 
    Loop 

    ReDim Preserve aryString(i - 1) As String ' i - 1 becuase of the final i = i + 1 
    RedimTestB = Timer - t 

End Function 

Answer 3

Cũng lưu ý rằng bạn chỉ có thể lấy lại kích thước phù hợp nhất của mảng đa chiều.