Tiện ích mở rộng gradle có thể xử lý đánh giá lười biếng của một thuộc tính không?

Question

Tôi đang viết một plugin gradle tùy chỉnh để xử lý một số công việc phức tạp mơ hồ và tôi đã gặp sự cố bực bội trong khi sử dụng các thuộc tính để định cấu hình một số tác vụ mà plugin áp dụng.

apply plugin: myPlugin 

//Provide properties for the applied plugin 
myPluginProps { 
    message = "Hello" 
} 

//Define a task that uses my custom task directly 
task thisTaskWorksFine(type: MyTask) { 
    input = myPluginProps.message 
} 

//Define a plugin that will apply a task of my custom type 
class MyPlugin implements Plugin<Project> { 
    void apply(Project project) { 
     project.extensions.create('myPluginProps', MyPluginExtension) 

     project.task(type: MyTask, 'thisTaskWorksIncorrectly') { 
      input = project.myPluginProps.message 
     } 
    } 
} 

//The extension used by my custom plugin to get input 
class MyPluginExtension { 
    def String message 
} 

//The task used by both the standard build section and the plugin 
class MyTask extends DefaultTask { 
    def String input 

    @TaskAction 
    def action() { 
     println "You gave me this: ${input}" 
    } 
} 

Kết quả từ việc sử dụng tập tin này như sau:

$ gradle thisTaskWorksFine thisTaskWorksIncorrectly 
:thisTaskWorksFine 
You gave me this: Hello 
:thisTaskWorksIncorrectly 
You gave me this: null 

BUILD SUCCESSFUL 

Tôi coi đây là rất bất ngờ. Để tâm trí của tôi, việc áp dụng một nhiệm vụ từ các plugin và viết một trực tiếp nên kết quả trong cùng một đầu ra khi đưa ra cùng một đầu vào. Trong trường hợp này, cả hai nhiệm vụ đều được cung cấp myPluginProps.message làm đầu vào, nhưng tác vụ được áp dụng bởi plugin là tham lam và đánh giá thành null sớm. (Trong quá trình áp dụng giai đoạn?)

Giải pháp duy nhất tôi đã tìm thấy là sử dụng đóng cửa trong khối cấu hình các nhiệm vụ plugin như vậy:

//Define a plugin that will apply a task of my custom type 
class MyPlugin implements Plugin<Project> { 
    void apply(Project project) { 
     project.extensions.create('myPluginProps', MyPluginExtension) 

     project.task(type: MyTask, 'thisTaskWorksIncorrectly') { 
      input = { project.myPluginProps.message } 
     } 
    } 
} 

Đó giải quyết vấn đề thẩm định tham lam khá độc đáo trừ mà bây giờ nhiệm vụ tùy chỉnh phải được sửa đổi để mong đợi và xử lý việc đóng cửa. Nó không phải là khó khăn để làm, nhưng tôi không nghĩ rằng nó phải là trách nhiệm của nhiệm vụ để đối phó với việc đóng cửa, kể từ khi plugin là "đổ lỗi".

Tôi có đang sử dụng tiện ích không chính xác tại đây không? Hoặc là họ chỉ không đủ? Quan điểm chính thức có vẻ như là we should use extensions nhưng tôi chưa tìm thấy bất kỳ ví dụ nào mà tiện ích mở rộng có thể làm những gì tôi cần. Tôi có thể di chuyển về phía trước với việc sử dụng các bao đóng và viết một loạt các getters boilerplate mà đóng cửa eval và setters có thể xử lý các bao đóng và các loại bình thường, nhưng nó có vẻ rất chống lại triết lý của groovy và do đó gradle. Tôi sẽ rất hạnh phúc nếu có một cách mà tôi có thể sử dụng phần mở rộng và nhận được đánh giá lười biếng tự động.

Answer 1

Giải pháp thông thường cho vấn đề này là sử dụng ước lập bản đồ:

class MyPlugin implements Plugin<Project> { 
    void apply(Project project) { 
     project.extensions.create('myPluginProps', MyPluginExtension) 

     project.task(type: MyTask, 'thisTaskWorksIncorrectly') { 
      conventionMapping.input = { project.myPluginProps.message } 
     } 
    } 
} 

và sau đó trong nhiệm vụ:

class MyTask extends DefaultTask { 
    def String input 

    @TaskAction 
    def action() { 
     println "You gave me this: ${getInput()}" 
    } 

}

Xin lưu ý rằng tôi dứt khoát dùng getter cho input - ánh xạ quy ước sẽ không khởi động nếu bạn tham chiếu trực tiếp đến trường.

Answer 2

Câu trả lời của Peter trong câu hỏi của tôi here cho biết rằng tính năng conventionMapping chắc chắn sẽ biến mất. Tốt nhất là tránh nó.

Sử dụng afterEvaluate để giải quyết vấn đề cấu hình hoãn lại bị hoãn đã làm cho mã của tôi sạch hơn rất nhiều so với cách tiếp cận ConventionMapping.

class MyPlugin implements Plugin<Project> { 
    void apply(Project project) { 
     project.extensions.create('myPluginProps', MyPluginExtension) 

     project.afterEvaluate { 
      project.task(type: MyTask, 'thisTaskWorksIncorrectly') { 
       input = project.myPluginProps.message 
      } 
     } 
    } 
}