Đánh giá [] dường như không hoạt động bên trong Nút []

Question

Bất kỳ ý tưởng nào về cách làm việc này?

y = {}; Table[Button[x, AppendTo[y, Evaluate[x]]], {x, 5}] 

Kết quả: Nhấp vào [1], nhấn [2], có {6,6}

Tôi đang tầm thường hóa các nhiệm vụ thực tế, nhưng mục đích là để thiết lập những gì một nút thực hiện bên trong một Map hoặc một Table hoặc ParallelTable.

Vui lòng trợ giúp!

---

EDIT
đặn nó ra ... Evaluate tác phẩm chỉ ở mức độ đầu tiên. Ở đây, nó quá sâu. Vì vậy, tôi sử dụng ReplaceRule:

Remove[sub]; y = {}; Table[Button[x, AppendTo[y, sub]] /. sub -> x, {x, 5}] 

Answer 1

thay thế và chức năng tinh khiết cung cấp lựa chọn thay thế ngắn gọn để With. Ví dụ:

y={}; Range[5] /. x_Integer :> Button[x, AppendTo[y, x]] 

hoặc

y = {}; Replace[Range[5], x_ :> Button[x, AppendTo[y, x]], {1}] 

hoặc

y = {}; Array[Button[#, AppendTo[y, #]] &, {5}] 

hoặc

y = {}; Button[#, AppendTo[y, #]] & /@ Range[5] 

Đối với một ví dụ so sánh những kỹ thuật này, xem bài của tôi here, nơi chúng được áp dụng để một prob lem của việc tạo ra một danh sách các chức năng tinh khiết với tham số nhúng trong cơ thể của họ (đóng cửa).

Answer 2

Đây là một công việc cho With. With được sử dụng để chèn một biểu thức được đánh giá vào một biểu hiện ở bất kỳ độ sâu - thậm chí thành phần của biểu thức không được đánh giá ngay lập tức như đối số thứ hai để Button:

y = {}; Table[With[{x = i}, Button[x, AppendTo[y, x]]], {i, 5}] 

Trong trường hợp đơn giản như thế này, một số người (trong đó có tôi) thích sử dụng cùng một biểu tượng (x trong trường hợp này) cho cả các biến With và Table, như sau: quy tắc

y = {}; Table[With[{x = x}, Button[x, AppendTo[y, x]]], {x, 5}] 

Answer 3

Evaluate chỉ hoạt động ở cấp độ đầu tiên. Ở đây, nó quá sâu. Vì vậy, tôi đã sử dụng ReplaceRule:

Remove[sub]; y = {}; Table[ Button[x, AppendTo[y, sub]] /. sub -> x, {x, 5}]