Chuyển đổi chuỗi UTF-8 thành ISO-8859-1

Question

Ứng dụng ASP cổ điển của tôi truy xuất chuỗi UTF-8 từ cơ sở dữ liệu của nó, nhưng tôi cần chuyển đổi nó thành ISO-8859-1. Tôi không thể thay đổi mã HTML trang;

Tôi thực sự chỉ cần chuyển đổi chuỗi đã tìm nạp. Tôi làm nó như thế nào?

Answer 1

Tôi tìm thấy câu trả lời here:

Const adTypeBinary = 1 
Const adTypeText = 2 

' accept a string and convert it to Bytes array in the selected Charset 
Function StringToBytes(Str,Charset) 
    Dim Stream : Set Stream = Server.CreateObject("ADODB.Stream") 
    Stream.Type = adTypeText 
    Stream.Charset = Charset 
    Stream.Open 
    Stream.WriteText Str 
    Stream.Flush 
    Stream.Position = 0 
    ' rewind stream and read Bytes 
    Stream.Type = adTypeBinary 
    StringToBytes= Stream.Read 
    Stream.Close 
    Set Stream = Nothing 
End Function 

' accept Bytes array and convert it to a string using the selected charset 
Function BytesToString(Bytes, Charset) 
    Dim Stream : Set Stream = Server.CreateObject("ADODB.Stream") 
    Stream.Charset = Charset 
    Stream.Type = adTypeBinary 
    Stream.Open 
    Stream.Write Bytes 
    Stream.Flush 
    Stream.Position = 0 
    ' rewind stream and read text 
    Stream.Type = adTypeText 
    BytesToString= Stream.ReadText 
    Stream.Close 
    Set Stream = Nothing 
End Function 

' This will alter charset of a string from 1-byte charset(as windows-1252) 
' to another 1-byte charset(as windows-1251) 
Function AlterCharset(Str, FromCharset, ToCharset) 
    Dim Bytes 
    Bytes = StringToBytes(Str, FromCharset) 
    AlterCharset = BytesToString(Bytes, ToCharset) 
End Function 

Vì vậy, tôi chỉ làm điều này:

AlterCharset(str, "ISO-8859-1", "UTF-8") 

Và nó làm việc độc đáo.

Answer 2

Để mở rộng tự tự câu trả lời của OP, khi chuyển đổi từ bộ ký tự single-byte (như ISO-8859-1, Windows-1251, Windows-1252, vv ...) để UTF-8, có một số dư thừa không cần thiết trong việc chuyển đổi đến và đi trở lại từ Mảng byte của ADODB. Chi phí của nhiều cuộc gọi chức năng và chuyển đổi có thể được loại bỏ như vậy:

Const adTypeText = 2 

Private Function AsciiStringToUTF8(AsciiString) 
    Dim objStream: Set objStream = CreateObject("ADODB.Stream") 
    Call objStream.Open() 
    objStream.Type = adTypeText 
    'Any single-byte charset should work in theory 
    objStream.Charset = "Windows-1252" 
    Call objStream.WriteText(AsciiString) 
    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''' 
    objStream.Position = 0 
    objStream.Charset = "UTF-8" 
    AsciiStringToUTF8 = objStream.ReadText() 
    Call objStream.Close(): Set objStream = Nothing 
End Function