Trong Perl, làm thế nào tôi có thể lặp qua nhiều phần tử của một mảng?

Question

Tôi có tệp CSV mà tôi sử dụng split để phân tích thành một mảng của N mục, trong đó N là bội số của 3.

Có cách nào tôi có thể làm điều này

foreach my ($a, $b, $c) (@d) {} 

tương tự như Python?

Answer 1

bạn có thể sử dụng List::MoreUtils::natatime Từ các tài liệu:.

my @x = ('a' .. 'g'); 
my $it = natatime 3, @x; 
while (my @vals = $it->()) { 
    print "@vals\n"; 
} 

natatime được thực hiện trong XS vì vậy bạn nên thích nó cho hiệu quả Chỉ cần cho mục đích minh hoạ, đây là cách người ta có thể thực hiện một ba. trình tạo biến tố phần tử trong Perl:

#!/usr/bin/perl 

use strict; use warnings; 

my @v = ('a' .. 'z'); 

my $it = make_3it(\@v); 

while (my @tuple = $it->()) { 
    print "@tuple\n"; 
} 

sub make_3it { 
    my ($arr) = @_; 
    { 
     my $lower = 0; 
     return sub { 
      return unless $lower < @$arr; 
      my $upper = $lower + 2; 
      @$arr > $upper or $upper = $#$arr; 
      my @ret = @$arr[$lower .. $upper]; 
      $lower = $upper + 1; 
      return @ret; 
     } 
    } 
} 

Answer 2

@z=(1,2,3,4,5,6,7,8,9,0); 

for(@tuple=splice(@z,0,3); @tuple; @tuple=splice(@z,0,3)) 
{ 
    print "$tuple[0] $tuple[1] $tuple[2]\n"; 
} 

sản xuất:

1 2 3 
4 5 6 
7 8 9 
0 

Answer 3

Không dễ dàng. Bạn muốn được tốt hơn làm @d một mảng của các bộ ba yếu tố, bằng cách đẩy các yếu tố vào mảng như một tài liệu tham khảo mảng:

foreach my $line (<>) 
    push @d, [ split /,/, $line ]; 

(Trừ mà bạn thực sự nên sử dụng một trong các module CSV từ CPAN .

Answer 4

Tôi đã giải quyết vấn đề này trong mô-đun List::Gen trên CPAN.

use List::Gen qw/by/; 

for my $items (by 3 => @list) { 

    # do something with @$items which will contain 3 element slices of @list 

    # unlike natatime or other common solutions, the elements in @$items are 
    # aliased to @list, just like in a normal foreach loop 

} 

Bạn cũng có thể nhập khẩu các mapn chức năng, được sử dụng bởi List::Gen để thực hiện by:

use List::Gen qw/mapn/; 

mapn { 

    # do something with the slices in @_ 

} 3 => @list; 

Answer 5

my @list = (qw(one two three four five six seven eight nine)); 

while (my ($m, $n, $o) = splice (@list,0,3)) { 
    print "$m $n $o\n"; 
} 

đầu ra này:

one two three 
four five six 
seven eight nine