Làm cách nào để chuyển hai danh sách vào một chương trình con Perl?

Question

Có thể vượt qua hai danh sách này để một sub trong Perl, ví dụ:

sub Foo { 
my(@list1,@list2) = @_; 

} 

Tôi biết tôi có thể làm cho @_ hai danh sách, với mỗi sublist là đối số mong muốn, tôi chỉ tự hỏi nếu có một cách sạch

Answer 1

Vâng, nếu bạn muốn hai mảng bạn có thể sử dụng một nguyên mẫu:

sub foo (\@\@) { 
    my $arr1 = shift; 
    my $arr2 = shift; 

    # Access arrays as references 
} 

foo(@wiz, @waz); # @wiz and @waz won't be flattened. 

Nhưng có rất nhiều cách để có được xung quanh Prot otypes, và tôi thích tránh chúng ở hầu hết các nơi. Bạn có thể chỉ cần bỏ qua mẫu thử nghiệm và tự chuyển tham chiếu:

sub foo { 
    my $arr1 = shift; 
    my $arr2 = shift; 

    # Access arrays as references 
} 

foo(\@wiz, \@waz); # Pass in wiz/waz as refs 
foo([1,2,4],[3,5,6]); # Hard coded arrays 

Nếu bạn chưa làm việc với tài liệu tham khảo, hãy xem perlreftut để được hướng dẫn tốt.

Answer 2

Nếu bạn chuyển hai danh sách theo giá trị ... bạn sẽ nhận được một danh sách lớn trong @_.

my(@list1,@list2) = @_; không thực hiện bất kỳ ý nghĩa:

#!/usr/bin/perl 

sub test 
{ 
    my (@a, @b) = @_; 

    print "@a\n"; 
    print "@b\n"; 
} 

my @array1 = (1,2,3); 
my @array2 = (5,6,7); 

test(@array1, @array2); 

này sẽ kết thúc in:

1 2 3 5 6 7 
<blank line> 

Để vượt qua hai mảng, bạn sẽ cần phải vượt qua chúng bằng cách tham khảo:

test(\@array1, \@array2); 

Và trong phụ của bạn, bạn cần coi chúng là tham chiếu:

sub test 
{ 
    my ($arrayRef1, $arrayRef2) = @_; 
    print "@$arrayRef1\n"; 
    print "@$arrayRef2\n"; 
}